1 // Copyright 2015 The Go Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style
3 // license that can be found in the LICENSE file.
4
5 // Lowering arithmetic
6 (Add(64|32|16|8) ...) => (ADD(Q|L|L|L) ...)
7 (AddPtr ...) => (ADDQ ...)
8 (Add(32|64)F ...) => (ADDS(S|D) ...)
9
10 (Sub(64|32|16|8) ...) => (SUB(Q|L|L|L) ...)
11 (SubPtr ...) => (SUBQ ...)
12 (Sub(32|64)F ...) => (SUBS(S|D) ...)
13
14 (Mul(64|32|16|8) ...) => (MUL(Q|L|L|L) ...)
15 (Mul(32|64)F ...) => (MULS(S|D) ...)
16
17 (Select0 (Mul64uover x y)) => (Select0 <typ.UInt64> (MULQU x y))
18 (Select0 (Mul32uover x y)) => (Select0 <typ.UInt32> (MULLU x y))
19 (Select1 (Mul(64|32)uover x y)) => (SETO (Select1 <types.TypeFlags> (MUL(Q|L)U x y)))
20
21 (Hmul(64|32) ...) => (HMUL(Q|L) ...)
22 (Hmul(64|32)u ...) => (HMUL(Q|L)U ...)
23
24 (Div(64|32|16) [a] x y) => (Select0 (DIV(Q|L|W) [a] x y))
25 (Div8 x y) => (Select0 (DIVW (SignExt8to16 x) (SignExt8to16 y)))
26 (Div(64|32|16)u x y) => (Select0 (DIV(Q|L|W)U x y))
27 (Div8u x y) => (Select0 (DIVWU (ZeroExt8to16 x) (ZeroExt8to16 y)))
28 (Div(32|64)F ...) => (DIVS(S|D) ...)
29
30 (Select0 (Add64carry x y c)) =>
31 (Select0 <typ.UInt64> (ADCQ x y (Select1 <types.TypeFlags> (NEGLflags c))))
32 (Select1 (Add64carry x y c)) =>
33 (NEGQ <typ.UInt64> (SBBQcarrymask <typ.UInt64> (Select1 <types.TypeFlags> (ADCQ x y (Select1 <types.TypeFlags> (NEGLflags c))))))
34 (Select0 (Sub64borrow x y c)) =>
35 (Select0 <typ.UInt64> (SBBQ x y (Select1 <types.TypeFlags> (NEGLflags c))))
36 (Select1 (Sub64borrow x y c)) =>
37 (NEGQ <typ.UInt64> (SBBQcarrymask <typ.UInt64> (Select1 <types.TypeFlags> (SBBQ x y (Select1 <types.TypeFlags> (NEGLflags c))))))
38
39 // Optimize ADCQ and friends
40 (ADCQ x (MOVQconst [c]) carry) && is32Bit(c) => (ADCQconst x [int32(c)] carry)
41 (ADCQ x y (FlagEQ)) => (ADDQcarry x y)
42 (ADCQconst x [c] (FlagEQ)) => (ADDQconstcarry x [c])
43 (ADDQcarry x (MOVQconst [c])) && is32Bit(c) => (ADDQconstcarry x [int32(c)])
44 (SBBQ x (MOVQconst [c]) borrow) && is32Bit(c) => (SBBQconst x [int32(c)] borrow)
45 (SBBQ x y (FlagEQ)) => (SUBQborrow x y)
46 (SBBQconst x [c] (FlagEQ)) => (SUBQconstborrow x [c])
47 (SUBQborrow x (MOVQconst [c])) && is32Bit(c) => (SUBQconstborrow x [int32(c)])
48 (Select1 (NEGLflags (MOVQconst [0]))) => (FlagEQ)
49 (Select1 (NEGLflags (NEGQ (SBBQcarrymask x)))) => x
50
51
52 (Mul64uhilo ...) => (MULQU2 ...)
53 (Div128u ...) => (DIVQU2 ...)
54
55 (Avg64u ...) => (AVGQU ...)
56
57 (Mod(64|32|16) [a] x y) => (Select1 (DIV(Q|L|W) [a] x y))
58 (Mod8 x y) => (Select1 (DIVW (SignExt8to16 x) (SignExt8to16 y)))
59 (Mod(64|32|16)u x y) => (Select1 (DIV(Q|L|W)U x y))
60 (Mod8u x y) => (Select1 (DIVWU (ZeroExt8to16 x) (ZeroExt8to16 y)))
61
62 (And(64|32|16|8) ...) => (AND(Q|L|L|L) ...)
63 (Or(64|32|16|8) ...) => (OR(Q|L|L|L) ...)
64 (Xor(64|32|16|8) ...) => (XOR(Q|L|L|L) ...)
65 (Com(64|32|16|8) ...) => (NOT(Q|L|L|L) ...)
66
67 (Neg(64|32|16|8) ...) => (NEG(Q|L|L|L) ...)
68 (Neg32F x) => (PXOR x (MOVSSconst <typ.Float32> [float32(math.Copysign(0, -1))]))
69 (Neg64F x) => (PXOR x (MOVSDconst <typ.Float64> [math.Copysign(0, -1)]))
70
71 // Lowering boolean ops
72 (AndB ...) => (ANDL ...)
73 (OrB ...) => (ORL ...)
74 (Not x) => (XORLconst [1] x)
75
76 // Lowering pointer arithmetic
77 (OffPtr [off] ptr) && is32Bit(off) => (ADDQconst [int32(off)] ptr)
78 (OffPtr [off] ptr) => (ADDQ (MOVQconst [off]) ptr)
79
80 // Lowering other arithmetic
81 (Ctz64 x) && buildcfg.GOAMD64 >= 3 => (TZCNTQ x)
82 (Ctz32 x) && buildcfg.GOAMD64 >= 3 => (TZCNTL x)
83 (Ctz64 <t> x) && buildcfg.GOAMD64 < 3 => (CMOVQEQ (Select0 <t> (BSFQ x)) (MOVQconst <t> [64]) (Select1 <types.TypeFlags> (BSFQ x)))
84 (Ctz32 x) && buildcfg.GOAMD64 < 3 => (Select0 (BSFQ (BTSQconst <typ.UInt64> [32] x)))
85 (Ctz16 x) => (BSFL (ORLconst <typ.UInt32> [1<<16] x))
86 (Ctz8 x) => (BSFL (ORLconst <typ.UInt32> [1<<8 ] x))
87
88 (Ctz64NonZero x) && buildcfg.GOAMD64 >= 3 => (TZCNTQ x)
89 (Ctz32NonZero x) && buildcfg.GOAMD64 >= 3 => (TZCNTL x)
90 (Ctz16NonZero x) && buildcfg.GOAMD64 >= 3 => (TZCNTL x)
91 (Ctz8NonZero x) && buildcfg.GOAMD64 >= 3 => (TZCNTL x)
92 (Ctz64NonZero x) && buildcfg.GOAMD64 < 3 => (Select0 (BSFQ x))
93 (Ctz32NonZero x) && buildcfg.GOAMD64 < 3 => (BSFL x)
94 (Ctz16NonZero x) && buildcfg.GOAMD64 < 3 => (BSFL x)
95 (Ctz8NonZero x) && buildcfg.GOAMD64 < 3 => (BSFL x)
96
97 // BitLen64 of a 64 bit value x requires checking whether x == 0, since BSRQ is undefined when x == 0.
98 // However, for zero-extended values, we can cheat a bit, and calculate
99 // BSR(x<<1 + 1), which is guaranteed to be non-zero, and which conveniently
100 // places the index of the highest set bit where we want it.
101 // For GOAMD64>=3, BitLen can be calculated by OperandSize - LZCNT(x).
102 (BitLen64 <t> x) && buildcfg.GOAMD64 < 3 => (ADDQconst [1] (CMOVQEQ <t> (Select0 <t> (BSRQ x)) (MOVQconst <t> [-1]) (Select1 <types.TypeFlags> (BSRQ x))))
103 (BitLen32 x) && buildcfg.GOAMD64 < 3 => (Select0 (BSRQ (LEAQ1 <typ.UInt64> [1] (MOVLQZX <typ.UInt64> x) (MOVLQZX <typ.UInt64> x))))
104 (BitLen16 x) && buildcfg.GOAMD64 < 3 => (BSRL (LEAL1 <typ.UInt32> [1] (MOVWQZX <typ.UInt32> x) (MOVWQZX <typ.UInt32> x)))
105 (BitLen8 x) && buildcfg.GOAMD64 < 3 => (BSRL (LEAL1 <typ.UInt32> [1] (MOVBQZX <typ.UInt32> x) (MOVBQZX <typ.UInt32> x)))
106 (BitLen64 <t> x) && buildcfg.GOAMD64 >= 3 => (NEGQ (ADDQconst <t> [-64] (LZCNTQ x)))
107 // Use 64-bit version to allow const-fold remove unnecessary arithmetic.
108 (BitLen32 <t> x) && buildcfg.GOAMD64 >= 3 => (NEGQ (ADDQconst <t> [-32] (LZCNTL x)))
109 (BitLen16 <t> x) && buildcfg.GOAMD64 >= 3 => (NEGQ (ADDQconst <t> [-32] (LZCNTL (MOVWQZX <x.Type> x))))
110 (BitLen8 <t> x) && buildcfg.GOAMD64 >= 3 => (NEGQ (ADDQconst <t> [-32] (LZCNTL (MOVBQZX <x.Type> x))))
111
112 (Bswap(64|32) ...) => (BSWAP(Q|L) ...)
113 (Bswap16 x) => (ROLWconst [8] x)
114
115 (PopCount(64|32) ...) => (POPCNT(Q|L) ...)
116 (PopCount16 x) => (POPCNTL (MOVWQZX <typ.UInt32> x))
117 (PopCount8 x) => (POPCNTL (MOVBQZX <typ.UInt32> x))
118
119 (Sqrt ...) => (SQRTSD ...)
120 (Sqrt32 ...) => (SQRTSS ...)
121
122 (RoundToEven x) => (ROUNDSD [0] x)
123 (Floor x) => (ROUNDSD [1] x)
124 (Ceil x) => (ROUNDSD [2] x)
125 (Trunc x) => (ROUNDSD [3] x)
126
127 (FMA x y z) => (VFMADD231SD z x y)
128
129 // Lowering extension
130 // Note: we always extend to 64 bits even though some ops don't need that many result bits.
131 (SignExt8to16 ...) => (MOVBQSX ...)
132 (SignExt8to32 ...) => (MOVBQSX ...)
133 (SignExt8to64 ...) => (MOVBQSX ...)
134 (SignExt16to32 ...) => (MOVWQSX ...)
135 (SignExt16to64 ...) => (MOVWQSX ...)
136 (SignExt32to64 ...) => (MOVLQSX ...)
137
138 (ZeroExt8to16 ...) => (MOVBQZX ...)
139 (ZeroExt8to32 ...) => (MOVBQZX ...)
140 (ZeroExt8to64 ...) => (MOVBQZX ...)
141 (ZeroExt16to32 ...) => (MOVWQZX ...)
142 (ZeroExt16to64 ...) => (MOVWQZX ...)
143 (ZeroExt32to64 ...) => (MOVLQZX ...)
144
145 (Slicemask <t> x) => (SARQconst (NEGQ <t> x) [63])
146
147 (SpectreIndex <t> x y) => (CMOVQCC x (MOVQconst [0]) (CMPQ x y))
148 (SpectreSliceIndex <t> x y) => (CMOVQHI x (MOVQconst [0]) (CMPQ x y))
149
150 // Lowering truncation
151 // Because we ignore high parts of registers, truncates are just copies.
152 (Trunc16to8 ...) => (Copy ...)
153 (Trunc32to8 ...) => (Copy ...)
154 (Trunc32to16 ...) => (Copy ...)
155 (Trunc64to8 ...) => (Copy ...)
156 (Trunc64to16 ...) => (Copy ...)
157 (Trunc64to32 ...) => (Copy ...)
158
159 // Lowering float <-> int
160 (Cvt32to32F ...) => (CVTSL2SS ...)
161 (Cvt32to64F ...) => (CVTSL2SD ...)
162 (Cvt64to32F ...) => (CVTSQ2SS ...)
163 (Cvt64to64F ...) => (CVTSQ2SD ...)
164
165 (Cvt32Fto32 ...) => (CVTTSS2SL ...)
166 (Cvt32Fto64 ...) => (CVTTSS2SQ ...)
167 (Cvt64Fto32 ...) => (CVTTSD2SL ...)
168 (Cvt64Fto64 ...) => (CVTTSD2SQ ...)
169
170 (Cvt32Fto64F ...) => (CVTSS2SD ...)
171 (Cvt64Fto32F ...) => (CVTSD2SS ...)
172
173 (Round(32|64)F ...) => (LoweredRound(32|64)F ...)
174
175 // Floating-point min is tricky, as the hardware op isn't right for various special
176 // cases (-0 and NaN). We use two hardware ops organized just right to make the
177 // result come out how we want it. See https://github.com/golang/go/issues/59488#issuecomment-1553493207
178 // (although that comment isn't exactly right, as the value overwritten is not simulated correctly).
179 // t1 = MINSD x, y => incorrect if x==NaN or x==-0,y==+0
180 // t2 = MINSD t1, x => fixes x==NaN case
181 // res = POR t1, t2 => fixes x==-0,y==+0 case
182 // Note that this trick depends on the special property that (NaN OR x) produces a NaN (although
183 // it might not produce the same NaN as the input).
184 (Min(64|32)F <t> x y) => (POR (MINS(D|S) <t> (MINS(D|S) <t> x y) x) (MINS(D|S) <t> x y))
185 // Floating-point max is even trickier. Punt to using min instead.
186 // max(x,y) == -min(-x,-y)
187 (Max(64|32)F <t> x y) => (Neg(64|32)F <t> (Min(64|32)F <t> (Neg(64|32)F <t> x) (Neg(64|32)F <t> y)))
188
189 (CvtBoolToUint8 ...) => (Copy ...)
190
191 // Lowering shifts
192 // Unsigned shifts need to return 0 if shift amount is >= width of shifted value.
193 // result = (arg << shift) & (shift >= argbits ? 0 : 0xffffffffffffffff)
194 (Lsh64x(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (ANDQ (SHLQ <t> x y) (SBBQcarrymask <t> (CMP(Q|L|W|B)const y [64])))
195 (Lsh32x(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (ANDL (SHLL <t> x y) (SBBLcarrymask <t> (CMP(Q|L|W|B)const y [32])))
196 (Lsh16x(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (ANDL (SHLL <t> x y) (SBBLcarrymask <t> (CMP(Q|L|W|B)const y [32])))
197 (Lsh8x(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (ANDL (SHLL <t> x y) (SBBLcarrymask <t> (CMP(Q|L|W|B)const y [32])))
198
199 (Lsh64x(64|32|16|8) x y) && shiftIsBounded(v) => (SHLQ x y)
200 (Lsh32x(64|32|16|8) x y) && shiftIsBounded(v) => (SHLL x y)
201 (Lsh16x(64|32|16|8) x y) && shiftIsBounded(v) => (SHLL x y)
202 (Lsh8x(64|32|16|8) x y) && shiftIsBounded(v) => (SHLL x y)
203
204 (Rsh64Ux(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (ANDQ (SHRQ <t> x y) (SBBQcarrymask <t> (CMP(Q|L|W|B)const y [64])))
205 (Rsh32Ux(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (ANDL (SHRL <t> x y) (SBBLcarrymask <t> (CMP(Q|L|W|B)const y [32])))
206 (Rsh16Ux(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (ANDL (SHRW <t> x y) (SBBLcarrymask <t> (CMP(Q|L|W|B)const y [16])))
207 (Rsh8Ux(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (ANDL (SHRB <t> x y) (SBBLcarrymask <t> (CMP(Q|L|W|B)const y [8])))
208
209 (Rsh64Ux(64|32|16|8) x y) && shiftIsBounded(v) => (SHRQ x y)
210 (Rsh32Ux(64|32|16|8) x y) && shiftIsBounded(v) => (SHRL x y)
211 (Rsh16Ux(64|32|16|8) x y) && shiftIsBounded(v) => (SHRW x y)
212 (Rsh8Ux(64|32|16|8) x y) && shiftIsBounded(v) => (SHRB x y)
213
214 // Signed right shift needs to return 0/-1 if shift amount is >= width of shifted value.
215 // We implement this by setting the shift value to -1 (all ones) if the shift value is >= width.
216 (Rsh64x(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (SARQ <t> x (OR(Q|L|L|L) <y.Type> y (NOT(Q|L|L|L) <y.Type> (SBB(Q|L|L|L)carrymask <y.Type> (CMP(Q|L|W|B)const y [64])))))
217 (Rsh32x(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (SARL <t> x (OR(Q|L|L|L) <y.Type> y (NOT(Q|L|L|L) <y.Type> (SBB(Q|L|L|L)carrymask <y.Type> (CMP(Q|L|W|B)const y [32])))))
218 (Rsh16x(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (SARW <t> x (OR(Q|L|L|L) <y.Type> y (NOT(Q|L|L|L) <y.Type> (SBB(Q|L|L|L)carrymask <y.Type> (CMP(Q|L|W|B)const y [16])))))
219 (Rsh8x(64|32|16|8) <t> x y) && !shiftIsBounded(v) => (SARB <t> x (OR(Q|L|L|L) <y.Type> y (NOT(Q|L|L|L) <y.Type> (SBB(Q|L|L|L)carrymask <y.Type> (CMP(Q|L|W|B)const y [8])))))
220
221 (Rsh64x(64|32|16|8) x y) && shiftIsBounded(v) => (SARQ x y)
222 (Rsh32x(64|32|16|8) x y) && shiftIsBounded(v) => (SARL x y)
223 (Rsh16x(64|32|16|8) x y) && shiftIsBounded(v) => (SARW x y)
224 (Rsh8x(64|32|16|8) x y) && shiftIsBounded(v) => (SARB x y)
225
226 // Lowering integer comparisons
227 (Less(64|32|16|8) x y) => (SETL (CMP(Q|L|W|B) x y))
228 (Less(64|32|16|8)U x y) => (SETB (CMP(Q|L|W|B) x y))
229 (Leq(64|32|16|8) x y) => (SETLE (CMP(Q|L|W|B) x y))
230 (Leq(64|32|16|8)U x y) => (SETBE (CMP(Q|L|W|B) x y))
231 (Eq(Ptr|64|32|16|8|B) x y) => (SETEQ (CMP(Q|Q|L|W|B|B) x y))
232 (Neq(Ptr|64|32|16|8|B) x y) => (SETNE (CMP(Q|Q|L|W|B|B) x y))
233
234 // Lowering floating point comparisons
235 // Note Go assembler gets UCOMISx operand order wrong, but it is right here
236 // and the operands are reversed when generating assembly language.
237 (Eq(32|64)F x y) => (SETEQF (UCOMIS(S|D) x y))
238 (Neq(32|64)F x y) => (SETNEF (UCOMIS(S|D) x y))
239 // Use SETGF/SETGEF with reversed operands to dodge NaN case.
240 (Less(32|64)F x y) => (SETGF (UCOMIS(S|D) y x))
241 (Leq(32|64)F x y) => (SETGEF (UCOMIS(S|D) y x))
242
243 // Lowering loads
244 (Load <t> ptr mem) && (is64BitInt(t) || isPtr(t)) => (MOVQload ptr mem)
245 (Load <t> ptr mem) && is32BitInt(t) => (MOVLload ptr mem)
246 (Load <t> ptr mem) && is16BitInt(t) => (MOVWload ptr mem)
247 (Load <t> ptr mem) && (t.IsBoolean() || is8BitInt(t)) => (MOVBload ptr mem)
248 (Load <t> ptr mem) && is32BitFloat(t) => (MOVSSload ptr mem)
249 (Load <t> ptr mem) && is64BitFloat(t) => (MOVSDload ptr mem)
250
251 // Lowering stores
252 (Store {t} ptr val mem) && t.Size() == 8 && t.IsFloat() => (MOVSDstore ptr val mem)
253 (Store {t} ptr val mem) && t.Size() == 4 && t.IsFloat() => (MOVSSstore ptr val mem)
254 (Store {t} ptr val mem) && t.Size() == 8 && !t.IsFloat() => (MOVQstore ptr val mem)
255 (Store {t} ptr val mem) && t.Size() == 4 && !t.IsFloat() => (MOVLstore ptr val mem)
256 (Store {t} ptr val mem) && t.Size() == 2 => (MOVWstore ptr val mem)
257 (Store {t} ptr val mem) && t.Size() == 1 => (MOVBstore ptr val mem)
258
259 // Lowering moves
260 (Move [0] _ _ mem) => mem
261 (Move [1] dst src mem) => (MOVBstore dst (MOVBload src mem) mem)
262 (Move [2] dst src mem) => (MOVWstore dst (MOVWload src mem) mem)
263 (Move [4] dst src mem) => (MOVLstore dst (MOVLload src mem) mem)
264 (Move [8] dst src mem) => (MOVQstore dst (MOVQload src mem) mem)
265 (Move [16] dst src mem) => (MOVOstore dst (MOVOload src mem) mem)
266
267 (Move [32] dst src mem) =>
268 (Move [16]
269 (OffPtr <dst.Type> dst [16])
270 (OffPtr <src.Type> src [16])
271 (Move [16] dst src mem))
272
273 (Move [48] dst src mem) =>
274 (Move [32]
275 (OffPtr <dst.Type> dst [16])
276 (OffPtr <src.Type> src [16])
277 (Move [16] dst src mem))
278
279 (Move [64] dst src mem) =>
280 (Move [32]
281 (OffPtr <dst.Type> dst [32])
282 (OffPtr <src.Type> src [32])
283 (Move [32] dst src mem))
284
285 (Move [3] dst src mem) =>
286 (MOVBstore [2] dst (MOVBload [2] src mem)
287 (MOVWstore dst (MOVWload src mem) mem))
288 (Move [5] dst src mem) =>
289 (MOVBstore [4] dst (MOVBload [4] src mem)
290 (MOVLstore dst (MOVLload src mem) mem))
291 (Move [6] dst src mem) =>
292 (MOVWstore [4] dst (MOVWload [4] src mem)
293 (MOVLstore dst (MOVLload src mem) mem))
294 (Move [7] dst src mem) =>
295 (MOVLstore [3] dst (MOVLload [3] src mem)
296 (MOVLstore dst (MOVLload src mem) mem))
297 (Move [9] dst src mem) =>
298 (MOVBstore [8] dst (MOVBload [8] src mem)
299 (MOVQstore dst (MOVQload src mem) mem))
300 (Move [10] dst src mem) =>
301 (MOVWstore [8] dst (MOVWload [8] src mem)
302 (MOVQstore dst (MOVQload src mem) mem))
303 (Move [11] dst src mem) =>
304 (MOVLstore [7] dst (MOVLload [7] src mem)
305 (MOVQstore dst (MOVQload src mem) mem))
306 (Move [12] dst src mem) =>
307 (MOVLstore [8] dst (MOVLload [8] src mem)
308 (MOVQstore dst (MOVQload src mem) mem))
309 (Move [s] dst src mem) && s >= 13 && s <= 15 =>
310 (MOVQstore [int32(s-8)] dst (MOVQload [int32(s-8)] src mem)
311 (MOVQstore dst (MOVQload src mem) mem))
312
313 // Adjust moves to be a multiple of 16 bytes.
314 (Move [s] dst src mem)
315 && s > 16 && s%16 != 0 && s%16 <= 8 =>
316 (Move [s-s%16]
317 (OffPtr <dst.Type> dst [s%16])
318 (OffPtr <src.Type> src [s%16])
319 (MOVQstore dst (MOVQload src mem) mem))
320 (Move [s] dst src mem)
321 && s > 16 && s%16 != 0 && s%16 > 8 =>
322 (Move [s-s%16]
323 (OffPtr <dst.Type> dst [s%16])
324 (OffPtr <src.Type> src [s%16])
325 (MOVOstore dst (MOVOload src mem) mem))
326
327 // Medium copying uses a duff device.
328 (Move [s] dst src mem)
329 && s > 64 && s <= 16*64 && s%16 == 0
330 && logLargeCopy(v, s) =>
331 (DUFFCOPY [s] dst src mem)
332
333 // Large copying uses REP MOVSQ.
334 (Move [s] dst src mem) && s > 16*64 && s%8 == 0 && logLargeCopy(v, s) =>
335 (REPMOVSQ dst src (MOVQconst [s/8]) mem)
336
337 // Lowering Zero instructions
338 (Zero [0] _ mem) => mem
339 (Zero [1] destptr mem) => (MOVBstoreconst [makeValAndOff(0,0)] destptr mem)
340 (Zero [2] destptr mem) => (MOVWstoreconst [makeValAndOff(0,0)] destptr mem)
341 (Zero [4] destptr mem) => (MOVLstoreconst [makeValAndOff(0,0)] destptr mem)
342 (Zero [8] destptr mem) => (MOVQstoreconst [makeValAndOff(0,0)] destptr mem)
343
344 (Zero [3] destptr mem) =>
345 (MOVBstoreconst [makeValAndOff(0,2)] destptr
346 (MOVWstoreconst [makeValAndOff(0,0)] destptr mem))
347 (Zero [5] destptr mem) =>
348 (MOVBstoreconst [makeValAndOff(0,4)] destptr
349 (MOVLstoreconst [makeValAndOff(0,0)] destptr mem))
350 (Zero [6] destptr mem) =>
351 (MOVWstoreconst [makeValAndOff(0,4)] destptr
352 (MOVLstoreconst [makeValAndOff(0,0)] destptr mem))
353 (Zero [7] destptr mem) =>
354 (MOVLstoreconst [makeValAndOff(0,3)] destptr
355 (MOVLstoreconst [makeValAndOff(0,0)] destptr mem))
356
357 // Zero small numbers of words directly.
358 (Zero [9] destptr mem) =>
359 (MOVBstoreconst [makeValAndOff(0,8)] destptr
360 (MOVQstoreconst [makeValAndOff(0,0)] destptr mem))
361
362 (Zero [10] destptr mem) =>
363 (MOVWstoreconst [makeValAndOff(0,8)] destptr
364 (MOVQstoreconst [makeValAndOff(0,0)] destptr mem))
365
366 (Zero [11] destptr mem) =>
367 (MOVLstoreconst [makeValAndOff(0,7)] destptr
368 (MOVQstoreconst [makeValAndOff(0,0)] destptr mem))
369
370 (Zero [12] destptr mem) =>
371 (MOVLstoreconst [makeValAndOff(0,8)] destptr
372 (MOVQstoreconst [makeValAndOff(0,0)] destptr mem))
373
374 (Zero [s] destptr mem) && s > 12 && s < 16 =>
375 (MOVQstoreconst [makeValAndOff(0,int32(s-8))] destptr
376 (MOVQstoreconst [makeValAndOff(0,0)] destptr mem))
377
378 // Zeroing up to 192 bytes uses straightline code.
379 (Zero [s] destptr mem) && s >= 16 && s < 192 => (LoweredZero [s] destptr mem)
380
381 // Zeroing up to ~1KB uses a small loop.
382 (Zero [s] destptr mem) && s >= 192 && s <= repZeroThreshold => (LoweredZeroLoop [s] destptr mem)
383
384 // Large zeroing uses REP STOSQ.
385 (Zero [s] destptr mem) && s > repZeroThreshold && s%8 != 0 =>
386 (Zero [s-s%8] (OffPtr <destptr.Type> destptr [s%8])
387 (MOVOstoreconst [makeValAndOff(0,0)] destptr mem))
388 (Zero [s] destptr mem) && s > repZeroThreshold && s%8 == 0 =>
389 (REPSTOSQ destptr (MOVQconst [s/8]) (MOVQconst [0]) mem)
390
391 // Lowering constants
392 (Const8 [c]) => (MOVLconst [int32(c)])
393 (Const16 [c]) => (MOVLconst [int32(c)])
394 (Const32 ...) => (MOVLconst ...)
395 (Const64 ...) => (MOVQconst ...)
396 (Const32F ...) => (MOVSSconst ...)
397 (Const64F ...) => (MOVSDconst ...)
398 (ConstNil ) => (MOVQconst [0])
399 (ConstBool [c]) => (MOVLconst [b2i32(c)])
400
401 // Lowering calls
402 (StaticCall ...) => (CALLstatic ...)
403 (ClosureCall ...) => (CALLclosure ...)
404 (InterCall ...) => (CALLinter ...)
405 (TailCall ...) => (CALLtail ...)
406
407 // Lowering conditional moves
408 // If the condition is a SETxx, we can just run a CMOV from the comparison that was
409 // setting the flags.
410 // Legend: HI=unsigned ABOVE, CS=unsigned BELOW, CC=unsigned ABOVE EQUAL, LS=unsigned BELOW EQUAL
411 (CondSelect <t> x y (SET(EQ|NE|L|G|LE|GE|A|B|AE|BE|EQF|NEF|GF|GEF) cond)) && (is64BitInt(t) || isPtr(t))
412 => (CMOVQ(EQ|NE|LT|GT|LE|GE|HI|CS|CC|LS|EQF|NEF|GTF|GEF) y x cond)
413 (CondSelect <t> x y (SET(EQ|NE|L|G|LE|GE|A|B|AE|BE|EQF|NEF|GF|GEF) cond)) && is32BitInt(t)
414 => (CMOVL(EQ|NE|LT|GT|LE|GE|HI|CS|CC|LS|EQF|NEF|GTF|GEF) y x cond)
415 (CondSelect <t> x y (SET(EQ|NE|L|G|LE|GE|A|B|AE|BE|EQF|NEF|GF|GEF) cond)) && is16BitInt(t)
416 => (CMOVW(EQ|NE|LT|GT|LE|GE|HI|CS|CC|LS|EQF|NEF|GTF|GEF) y x cond)
417
418 // If the condition does not set the flags, we need to generate a comparison.
419 (CondSelect <t> x y check) && !check.Type.IsFlags() && check.Type.Size() == 1
420 => (CondSelect <t> x y (MOVBQZX <typ.UInt64> check))
421 (CondSelect <t> x y check) && !check.Type.IsFlags() && check.Type.Size() == 2
422 => (CondSelect <t> x y (MOVWQZX <typ.UInt64> check))
423 (CondSelect <t> x y check) && !check.Type.IsFlags() && check.Type.Size() == 4
424 => (CondSelect <t> x y (MOVLQZX <typ.UInt64> check))
425
426 (CondSelect <t> x y check) && !check.Type.IsFlags() && check.Type.Size() == 8 && (is64BitInt(t) || isPtr(t))
427 => (CMOVQNE y x (CMPQconst [0] check))
428 (CondSelect <t> x y check) && !check.Type.IsFlags() && check.Type.Size() == 8 && is32BitInt(t)
429 => (CMOVLNE y x (CMPQconst [0] check))
430 (CondSelect <t> x y check) && !check.Type.IsFlags() && check.Type.Size() == 8 && is16BitInt(t)
431 => (CMOVWNE y x (CMPQconst [0] check))
432
433 // Absorb InvertFlags
434 (CMOVQ(EQ|NE|LT|GT|LE|GE|HI|CS|CC|LS) x y (InvertFlags cond))
435 => (CMOVQ(EQ|NE|GT|LT|GE|LE|CS|HI|LS|CC) x y cond)
436 (CMOVL(EQ|NE|LT|GT|LE|GE|HI|CS|CC|LS) x y (InvertFlags cond))
437 => (CMOVL(EQ|NE|GT|LT|GE|LE|CS|HI|LS|CC) x y cond)
438 (CMOVW(EQ|NE|LT|GT|LE|GE|HI|CS|CC|LS) x y (InvertFlags cond))
439 => (CMOVW(EQ|NE|GT|LT|GE|LE|CS|HI|LS|CC) x y cond)
440
441 // Absorb constants generated during lower
442 (CMOV(QEQ|QLE|QGE|QCC|QLS|LEQ|LLE|LGE|LCC|LLS|WEQ|WLE|WGE|WCC|WLS) _ x (FlagEQ)) => x
443 (CMOV(QNE|QLT|QGT|QCS|QHI|LNE|LLT|LGT|LCS|LHI|WNE|WLT|WGT|WCS|WHI) y _ (FlagEQ)) => y
444 (CMOV(QNE|QGT|QGE|QHI|QCC|LNE|LGT|LGE|LHI|LCC|WNE|WGT|WGE|WHI|WCC) _ x (FlagGT_UGT)) => x
445 (CMOV(QEQ|QLE|QLT|QLS|QCS|LEQ|LLE|LLT|LLS|LCS|WEQ|WLE|WLT|WLS|WCS) y _ (FlagGT_UGT)) => y
446 (CMOV(QNE|QGT|QGE|QLS|QCS|LNE|LGT|LGE|LLS|LCS|WNE|WGT|WGE|WLS|WCS) _ x (FlagGT_ULT)) => x
447 (CMOV(QEQ|QLE|QLT|QHI|QCC|LEQ|LLE|LLT|LHI|LCC|WEQ|WLE|WLT|WHI|WCC) y _ (FlagGT_ULT)) => y
448 (CMOV(QNE|QLT|QLE|QCS|QLS|LNE|LLT|LLE|LCS|LLS|WNE|WLT|WLE|WCS|WLS) _ x (FlagLT_ULT)) => x
449 (CMOV(QEQ|QGT|QGE|QHI|QCC|LEQ|LGT|LGE|LHI|LCC|WEQ|WGT|WGE|WHI|WCC) y _ (FlagLT_ULT)) => y
450 (CMOV(QNE|QLT|QLE|QHI|QCC|LNE|LLT|LLE|LHI|LCC|WNE|WLT|WLE|WHI|WCC) _ x (FlagLT_UGT)) => x
451 (CMOV(QEQ|QGT|QGE|QCS|QLS|LEQ|LGT|LGE|LCS|LLS|WEQ|WGT|WGE|WCS|WLS) y _ (FlagLT_UGT)) => y
452
453 // Miscellaneous
454 (IsNonNil p) => (SETNE (TESTQ p p))
455 (IsInBounds idx len) => (SETB (CMPQ idx len))
456 (IsSliceInBounds idx len) => (SETBE (CMPQ idx len))
457 (NilCheck ...) => (LoweredNilCheck ...)
458 (GetG mem) && v.Block.Func.OwnAux.Fn.ABI() != obj.ABIInternal => (LoweredGetG mem) // only lower in old ABI. in new ABI we have a G register.
459 (GetClosurePtr ...) => (LoweredGetClosurePtr ...)
460 (GetCallerPC ...) => (LoweredGetCallerPC ...)
461 (GetCallerSP ...) => (LoweredGetCallerSP ...)
462
463 (HasCPUFeature {s}) => (SETNE (CMPLconst [0] (LoweredHasCPUFeature {s})))
464 (Addr {sym} base) => (LEAQ {sym} base)
465 (LocalAddr <t> {sym} base mem) && t.Elem().HasPointers() => (LEAQ {sym} (SPanchored base mem))
466 (LocalAddr <t> {sym} base _) && !t.Elem().HasPointers() => (LEAQ {sym} base)
467
468 (MOVBstore [off] {sym} ptr y:(SETL x) mem) && y.Uses == 1 => (SETLstore [off] {sym} ptr x mem)
469 (MOVBstore [off] {sym} ptr y:(SETLE x) mem) && y.Uses == 1 => (SETLEstore [off] {sym} ptr x mem)
470 (MOVBstore [off] {sym} ptr y:(SETG x) mem) && y.Uses == 1 => (SETGstore [off] {sym} ptr x mem)
471 (MOVBstore [off] {sym} ptr y:(SETGE x) mem) && y.Uses == 1 => (SETGEstore [off] {sym} ptr x mem)
472 (MOVBstore [off] {sym} ptr y:(SETEQ x) mem) && y.Uses == 1 => (SETEQstore [off] {sym} ptr x mem)
473 (MOVBstore [off] {sym} ptr y:(SETNE x) mem) && y.Uses == 1 => (SETNEstore [off] {sym} ptr x mem)
474 (MOVBstore [off] {sym} ptr y:(SETB x) mem) && y.Uses == 1 => (SETBstore [off] {sym} ptr x mem)
475 (MOVBstore [off] {sym} ptr y:(SETBE x) mem) && y.Uses == 1 => (SETBEstore [off] {sym} ptr x mem)
476 (MOVBstore [off] {sym} ptr y:(SETA x) mem) && y.Uses == 1 => (SETAstore [off] {sym} ptr x mem)
477 (MOVBstore [off] {sym} ptr y:(SETAE x) mem) && y.Uses == 1 => (SETAEstore [off] {sym} ptr x mem)
478
479 // block rewrites
480 (If (SETL cmp) yes no) => (LT cmp yes no)
481 (If (SETLE cmp) yes no) => (LE cmp yes no)
482 (If (SETG cmp) yes no) => (GT cmp yes no)
483 (If (SETGE cmp) yes no) => (GE cmp yes no)
484 (If (SETEQ cmp) yes no) => (EQ cmp yes no)
485 (If (SETNE cmp) yes no) => (NE cmp yes no)
486 (If (SETB cmp) yes no) => (ULT cmp yes no)
487 (If (SETBE cmp) yes no) => (ULE cmp yes no)
488 (If (SETA cmp) yes no) => (UGT cmp yes no)
489 (If (SETAE cmp) yes no) => (UGE cmp yes no)
490 (If (SETO cmp) yes no) => (OS cmp yes no)
491
492 // Special case for floating point - LF/LEF not generated
493 (If (SETGF cmp) yes no) => (UGT cmp yes no)
494 (If (SETGEF cmp) yes no) => (UGE cmp yes no)
495 (If (SETEQF cmp) yes no) => (EQF cmp yes no)
496 (If (SETNEF cmp) yes no) => (NEF cmp yes no)
497
498 (If cond yes no) => (NE (TESTB cond cond) yes no)
499
500 (JumpTable idx) => (JUMPTABLE {makeJumpTableSym(b)} idx (LEAQ <typ.Uintptr> {makeJumpTableSym(b)} (SB)))
501
502 // Atomic loads. Other than preserving their ordering with respect to other loads, nothing special here.
503 (AtomicLoad8 ptr mem) => (MOVBatomicload ptr mem)
504 (AtomicLoad32 ptr mem) => (MOVLatomicload ptr mem)
505 (AtomicLoad64 ptr mem) => (MOVQatomicload ptr mem)
506 (AtomicLoadPtr ptr mem) => (MOVQatomicload ptr mem)
507
508 // Atomic stores. We use XCHG to prevent the hardware reordering a subsequent load.
509 // TODO: most runtime uses of atomic stores don't need that property. Use normal stores for those?
510 (AtomicStore8 ptr val mem) => (Select1 (XCHGB <types.NewTuple(typ.UInt8,types.TypeMem)> val ptr mem))
511 (AtomicStore32 ptr val mem) => (Select1 (XCHGL <types.NewTuple(typ.UInt32,types.TypeMem)> val ptr mem))
512 (AtomicStore64 ptr val mem) => (Select1 (XCHGQ <types.NewTuple(typ.UInt64,types.TypeMem)> val ptr mem))
513 (AtomicStorePtrNoWB ptr val mem) => (Select1 (XCHGQ <types.NewTuple(typ.BytePtr,types.TypeMem)> val ptr mem))
514
515 // Atomic exchanges.
516 (AtomicExchange8 ptr val mem) => (XCHGB val ptr mem)
517 (AtomicExchange32 ptr val mem) => (XCHGL val ptr mem)
518 (AtomicExchange64 ptr val mem) => (XCHGQ val ptr mem)
519
520 // Atomic adds.
521 (AtomicAdd32 ptr val mem) => (AddTupleFirst32 val (XADDLlock val ptr mem))
522 (AtomicAdd64 ptr val mem) => (AddTupleFirst64 val (XADDQlock val ptr mem))
523 (Select0 <t> (AddTupleFirst32 val tuple)) => (ADDL val (Select0 <t> tuple))
524 (Select1 (AddTupleFirst32 _ tuple)) => (Select1 tuple)
525 (Select0 <t> (AddTupleFirst64 val tuple)) => (ADDQ val (Select0 <t> tuple))
526 (Select1 (AddTupleFirst64 _ tuple)) => (Select1 tuple)
527
528 // Atomic compare and swap.
529 (AtomicCompareAndSwap32 ptr old new_ mem) => (CMPXCHGLlock ptr old new_ mem)
530 (AtomicCompareAndSwap64 ptr old new_ mem) => (CMPXCHGQlock ptr old new_ mem)
531
532 // Atomic memory logical operations (old style).
533 (AtomicAnd8 ptr val mem) => (ANDBlock ptr val mem)
534 (AtomicAnd32 ptr val mem) => (ANDLlock ptr val mem)
535 (AtomicOr8 ptr val mem) => (ORBlock ptr val mem)
536 (AtomicOr32 ptr val mem) => (ORLlock ptr val mem)
537
538 // Atomic memory logical operations (new style).
539 (Atomic(And64|And32|Or64|Or32)value ptr val mem) => (LoweredAtomic(And64|And32|Or64|Or32) ptr val mem)
540
541 // Write barrier.
542 (WB ...) => (LoweredWB ...)
543
544 (PanicBounds ...) => (LoweredPanicBoundsRR ...)
545 (LoweredPanicBoundsRR [kind] x (MOVQconst [c]) mem) => (LoweredPanicBoundsRC [kind] x {PanicBoundsC{C:c}} mem)
546 (LoweredPanicBoundsRR [kind] (MOVQconst [c]) y mem) => (LoweredPanicBoundsCR [kind] {PanicBoundsC{C:c}} y mem)
547 (LoweredPanicBoundsRC [kind] {p} (MOVQconst [c]) mem) => (LoweredPanicBoundsCC [kind] {PanicBoundsCC{Cx:c, Cy:p.C}} mem)
548 (LoweredPanicBoundsCR [kind] {p} (MOVQconst [c]) mem) => (LoweredPanicBoundsCC [kind] {PanicBoundsCC{Cx:p.C, Cy:c}} mem)
549
550 // lowering rotates
551 (RotateLeft8 ...) => (ROLB ...)
552 (RotateLeft16 ...) => (ROLW ...)
553 (RotateLeft32 ...) => (ROLL ...)
554 (RotateLeft64 ...) => (ROLQ ...)
555
556 // ***************************
557 // Above: lowering rules
558 // Below: optimizations
559 // ***************************
560 // TODO: Should the optimizations be a separate pass?
561
562 // Fold boolean tests into blocks
563 (NE (TESTB (SETL cmp) (SETL cmp)) yes no) => (LT cmp yes no)
564 (NE (TESTB (SETLE cmp) (SETLE cmp)) yes no) => (LE cmp yes no)
565 (NE (TESTB (SETG cmp) (SETG cmp)) yes no) => (GT cmp yes no)
566 (NE (TESTB (SETGE cmp) (SETGE cmp)) yes no) => (GE cmp yes no)
567 (NE (TESTB (SETEQ cmp) (SETEQ cmp)) yes no) => (EQ cmp yes no)
568 (NE (TESTB (SETNE cmp) (SETNE cmp)) yes no) => (NE cmp yes no)
569 (NE (TESTB (SETB cmp) (SETB cmp)) yes no) => (ULT cmp yes no)
570 (NE (TESTB (SETBE cmp) (SETBE cmp)) yes no) => (ULE cmp yes no)
571 (NE (TESTB (SETA cmp) (SETA cmp)) yes no) => (UGT cmp yes no)
572 (NE (TESTB (SETAE cmp) (SETAE cmp)) yes no) => (UGE cmp yes no)
573 (NE (TESTB (SETO cmp) (SETO cmp)) yes no) => (OS cmp yes no)
574
575 // Unsigned comparisons to 0/1
576 (ULT (TEST(Q|L|W|B) x x) yes no) => (First no yes)
577 (UGE (TEST(Q|L|W|B) x x) yes no) => (First yes no)
578 (SETB (TEST(Q|L|W|B) x x)) => (ConstBool [false])
579 (SETAE (TEST(Q|L|W|B) x x)) => (ConstBool [true])
580
581 // x & 1 != 0 -> x & 1
582 (SETNE (TEST(B|W)const [1] x)) => (AND(L|L)const [1] x)
583 (SETB (BT(L|Q)const [0] x)) => (AND(L|Q)const [1] x)
584 // x & 1 == 0 -> (x & 1) ^ 1
585 (SETAE (BT(L|Q)const [0] x)) => (XORLconst [1] (ANDLconst <typ.Bool> [1] x))
586
587 // Shorten compare by rewriting x < 128 as x <= 127, which can be encoded in a single-byte immediate on x86.
588 (SETL c:(CMP(Q|L)const [128] x)) && c.Uses == 1 => (SETLE (CMP(Q|L)const [127] x))
589 (SETB c:(CMP(Q|L)const [128] x)) && c.Uses == 1 => (SETBE (CMP(Q|L)const [127] x))
590
591 // x >= 128 -> x > 127
592 (SETGE c:(CMP(Q|L)const [128] x)) && c.Uses == 1 => (SETG (CMP(Q|L)const [127] x))
593 (SETAE c:(CMP(Q|L)const [128] x)) && c.Uses == 1 => (SETA (CMP(Q|L)const [127] x))
594
595 (CMOVQLT x y c:(CMP(Q|L)const [128] z)) && c.Uses == 1 => (CMOVQLE x y (CMP(Q|L)const [127] z))
596 (CMOVLLT x y c:(CMP(Q|L)const [128] z)) && c.Uses == 1 => (CMOVLLE x y (CMP(Q|L)const [127] z))
597 (LT c:(CMP(Q|L)const [128] z) yes no) && c.Uses == 1 => (LE (CMP(Q|L)const [127] z) yes no)
598 (CMOVQGE x y c:(CMP(Q|L)const [128] z)) && c.Uses == 1 => (CMOVQGT x y (CMP(Q|L)const [127] z))
599 (CMOVLGE x y c:(CMP(Q|L)const [128] z)) && c.Uses == 1 => (CMOVLGT x y (CMP(Q|L)const [127] z))
600 (GE c:(CMP(Q|L)const [128] z) yes no) && c.Uses == 1 => (GT (CMP(Q|L)const [127] z) yes no)
601
602 // Recognize bit tests: a&(1<<b) != 0 for b suitably bounded
603 // Note that BTx instructions use the carry bit, so we need to convert tests for zero flag
604 // into tests for carry flags.
605 // ULT and SETB check the carry flag; they are identical to CS and SETCS. Same, mutatis
606 // mutandis, for UGE and SETAE, and CC and SETCC.
607 ((NE|EQ) (TESTL (SHLL (MOVLconst [1]) x) y)) => ((ULT|UGE) (BTL x y))
608 ((NE|EQ) (TESTQ (SHLQ (MOVQconst [1]) x) y)) => ((ULT|UGE) (BTQ x y))
609 ((NE|EQ) (TESTLconst [c] x)) && isUnsignedPowerOfTwo(uint32(c))
610 => ((ULT|UGE) (BTLconst [int8(log32u(uint32(c)))] x))
611 ((NE|EQ) (TESTQconst [c] x)) && isUnsignedPowerOfTwo(uint64(c))
612 => ((ULT|UGE) (BTQconst [int8(log32u(uint32(c)))] x))
613 ((NE|EQ) (TESTQ (MOVQconst [c]) x)) && isUnsignedPowerOfTwo(uint64(c))
614 => ((ULT|UGE) (BTQconst [int8(log64u(uint64(c)))] x))
615 (SET(NE|EQ) (TESTL (SHLL (MOVLconst [1]) x) y)) => (SET(B|AE) (BTL x y))
616 (SET(NE|EQ) (TESTQ (SHLQ (MOVQconst [1]) x) y)) => (SET(B|AE) (BTQ x y))
617 (SET(NE|EQ) (TESTLconst [c] x)) && isUnsignedPowerOfTwo(uint32(c))
618 => (SET(B|AE) (BTLconst [int8(log32u(uint32(c)))] x))
619 (SET(NE|EQ) (TESTQconst [c] x)) && isUnsignedPowerOfTwo(uint64(c))
620 => (SET(B|AE) (BTQconst [int8(log32u(uint32(c)))] x))
621 (SET(NE|EQ) (TESTQ (MOVQconst [c]) x)) && isUnsignedPowerOfTwo(uint64(c))
622 => (SET(B|AE) (BTQconst [int8(log64u(uint64(c)))] x))
623 // SET..store variant
624 (SET(NE|EQ)store [off] {sym} ptr (TESTL (SHLL (MOVLconst [1]) x) y) mem)
625 => (SET(B|AE)store [off] {sym} ptr (BTL x y) mem)
626 (SET(NE|EQ)store [off] {sym} ptr (TESTQ (SHLQ (MOVQconst [1]) x) y) mem)
627 => (SET(B|AE)store [off] {sym} ptr (BTQ x y) mem)
628 (SET(NE|EQ)store [off] {sym} ptr (TESTLconst [c] x) mem) && isUnsignedPowerOfTwo(uint32(c))
629 => (SET(B|AE)store [off] {sym} ptr (BTLconst [int8(log32u(uint32(c)))] x) mem)
630 (SET(NE|EQ)store [off] {sym} ptr (TESTQconst [c] x) mem) && isUnsignedPowerOfTwo(uint64(c))
631 => (SET(B|AE)store [off] {sym} ptr (BTQconst [int8(log32u(uint32(c)))] x) mem)
632 (SET(NE|EQ)store [off] {sym} ptr (TESTQ (MOVQconst [c]) x) mem) && isUnsignedPowerOfTwo(uint64(c))
633 => (SET(B|AE)store [off] {sym} ptr (BTQconst [int8(log64u(uint64(c)))] x) mem)
634
635 // Handle bit-testing in the form (a>>b)&1 != 0 by building the above rules
636 // and further combining shifts.
637 (BT(Q|L)const [c] (SHRQconst [d] x)) && (c+d)<64 => (BTQconst [c+d] x)
638 (BT(Q|L)const [c] (ADDQ x x)) && c>1 => (BT(Q|L)const [c-1] x)
639 (BT(Q|L)const [c] (SHLQconst [d] x)) && c>d => (BT(Q|L)const [c-d] x)
640 (BT(Q|L)const [0] s:(SHRQ x y)) => (BTQ y x)
641 (BTLconst [c] (SHRLconst [d] x)) && (c+d)<32 => (BTLconst [c+d] x)
642 (BTLconst [c] (ADDL x x)) && c>1 => (BTLconst [c-1] x)
643 (BTLconst [c] (SHLLconst [d] x)) && c>d => (BTLconst [c-d] x)
644 (BTLconst [0] s:(SHR(L|XL) x y)) => (BTL y x)
645
646 // Rewrite a & 1 != 1 into a & 1 == 0.
647 // Among other things, this lets us turn (a>>b)&1 != 1 into a bit test.
648 (SET(NE|EQ) (CMPLconst [1] s:(ANDLconst [1] _))) => (SET(EQ|NE) (CMPLconst [0] s))
649 (SET(NE|EQ)store [off] {sym} ptr (CMPLconst [1] s:(ANDLconst [1] _)) mem) => (SET(EQ|NE)store [off] {sym} ptr (CMPLconst [0] s) mem)
650 (SET(NE|EQ) (CMPQconst [1] s:(ANDQconst [1] _))) => (SET(EQ|NE) (CMPQconst [0] s))
651 (SET(NE|EQ)store [off] {sym} ptr (CMPQconst [1] s:(ANDQconst [1] _)) mem) => (SET(EQ|NE)store [off] {sym} ptr (CMPQconst [0] s) mem)
652
653 // Recognize bit setting (a |= 1<<b) and toggling (a ^= 1<<b)
654 (OR(Q|L) (SHL(Q|L) (MOV(Q|L)const [1]) y) x) => (BTS(Q|L) x y)
655 (XOR(Q|L) (SHL(Q|L) (MOV(Q|L)const [1]) y) x) => (BTC(Q|L) x y)
656 // Note: only convert OR/XOR to BTS/BTC if the constant wouldn't fit in
657 // the constant field of the OR/XOR instruction. See issue 61694.
658 ((OR|XOR)Q (MOVQconst [c]) x) && isUnsignedPowerOfTwo(uint64(c)) && uint64(c) >= 1<<31 => (BT(S|C)Qconst [int8(log64u(uint64(c)))] x)
659
660 // Recognize bit clearing: a &^= 1<<b
661 (AND(Q|L) (NOT(Q|L) (SHL(Q|L) (MOV(Q|L)const [1]) y)) x) => (BTR(Q|L) x y)
662 (ANDN(Q|L) x (SHL(Q|L) (MOV(Q|L)const [1]) y)) => (BTR(Q|L) x y)
663 // Note: only convert AND to BTR if the constant wouldn't fit in
664 // the constant field of the AND instruction. See issue 61694.
665 (ANDQ (MOVQconst [c]) x) && isUnsignedPowerOfTwo(uint64(^c)) && uint64(^c) >= 1<<31 => (BTRQconst [int8(log64u(uint64(^c)))] x)
666
667 // Special-case bit patterns on first/last bit.
668 // generic.rules changes ANDs of high-part/low-part masks into a couple of shifts,
669 // for instance:
670 // x & 0xFFFF0000 -> (x >> 16) << 16
671 // x & 0x80000000 -> (x >> 31) << 31
672 //
673 // In case the mask is just one bit (like second example above), it conflicts
674 // with the above rules to detect bit-testing / bit-clearing of first/last bit.
675 // We thus special-case them, by detecting the shift patterns.
676
677 // Special case resetting first/last bit
678 (ADD(L|Q) (SHR(L|Q)const [1] x) (SHR(L|Q)const [1] x))
679 => (AND(L|Q)const [-2] x)
680 (SHRLconst [1] (ADDL x x))
681 => (ANDLconst [0x7fffffff] x)
682 (SHRQconst [1] (ADDQ x x))
683 => (BTRQconst [63] x)
684
685 // Special case testing first/last bit (with double-shift generated by generic.rules)
686 ((SETNE|SETEQ|NE|EQ) (TESTQ z1:(SHLQconst [63] (SHRQconst [63] x)) z2)) && z1==z2
687 => ((SETB|SETAE|ULT|UGE) (BTQconst [63] x))
688 ((SETNE|SETEQ|NE|EQ) (TESTL z1:(SHLLconst [31] (SHRQconst [31] x)) z2)) && z1==z2
689 => ((SETB|SETAE|ULT|UGE) (BTQconst [31] x))
690 (SET(NE|EQ)store [off] {sym} ptr (TESTQ z1:(SHLQconst [63] (SHRQconst [63] x)) z2) mem) && z1==z2
691 => (SET(B|AE)store [off] {sym} ptr (BTQconst [63] x) mem)
692 (SET(NE|EQ)store [off] {sym} ptr (TESTL z1:(SHLLconst [31] (SHRLconst [31] x)) z2) mem) && z1==z2
693 => (SET(B|AE)store [off] {sym} ptr (BTLconst [31] x) mem)
694
695 ((SETNE|SETEQ|NE|EQ) (TESTQ z1:(SHRQconst [63] (SHLQconst [63] x)) z2)) && z1==z2
696 => ((SETB|SETAE|ULT|UGE) (BTQconst [0] x))
697 ((SETNE|SETEQ|NE|EQ) (TESTL z1:(SHRLconst [31] (SHLLconst [31] x)) z2)) && z1==z2
698 => ((SETB|SETAE|ULT|UGE) (BTLconst [0] x))
699 (SET(NE|EQ)store [off] {sym} ptr (TESTQ z1:(SHRQconst [63] (SHLQconst [63] x)) z2) mem) && z1==z2
700 => (SET(B|AE)store [off] {sym} ptr (BTQconst [0] x) mem)
701 (SET(NE|EQ)store [off] {sym} ptr (TESTL z1:(SHRLconst [31] (SHLLconst [31] x)) z2) mem) && z1==z2
702 => (SET(B|AE)store [off] {sym} ptr (BTLconst [0] x) mem)
703
704 // Special-case manually testing last bit with "a>>63 != 0" (without "&1")
705 ((SETNE|SETEQ|NE|EQ) (TESTQ z1:(SHRQconst [63] x) z2)) && z1==z2
706 => ((SETB|SETAE|ULT|UGE) (BTQconst [63] x))
707 ((SETNE|SETEQ|NE|EQ) (TESTL z1:(SHRLconst [31] x) z2)) && z1==z2
708 => ((SETB|SETAE|ULT|UGE) (BTLconst [31] x))
709 (SET(NE|EQ)store [off] {sym} ptr (TESTQ z1:(SHRQconst [63] x) z2) mem) && z1==z2
710 => (SET(B|AE)store [off] {sym} ptr (BTQconst [63] x) mem)
711 (SET(NE|EQ)store [off] {sym} ptr (TESTL z1:(SHRLconst [31] x) z2) mem) && z1==z2
712 => (SET(B|AE)store [off] {sym} ptr (BTLconst [31] x) mem)
713
714 // Fold combinations of bit ops on same bit. An example is math.Copysign(c,-1)
715 (BTSQconst [c] (BTRQconst [c] x)) => (BTSQconst [c] x)
716 (BTSQconst [c] (BTCQconst [c] x)) => (BTSQconst [c] x)
717 (BTRQconst [c] (BTSQconst [c] x)) => (BTRQconst [c] x)
718 (BTRQconst [c] (BTCQconst [c] x)) => (BTRQconst [c] x)
719
720 // Fold boolean negation into SETcc.
721 (XORLconst [1] (SETNE x)) => (SETEQ x)
722 (XORLconst [1] (SETEQ x)) => (SETNE x)
723 (XORLconst [1] (SETL x)) => (SETGE x)
724 (XORLconst [1] (SETGE x)) => (SETL x)
725 (XORLconst [1] (SETLE x)) => (SETG x)
726 (XORLconst [1] (SETG x)) => (SETLE x)
727 (XORLconst [1] (SETB x)) => (SETAE x)
728 (XORLconst [1] (SETAE x)) => (SETB x)
729 (XORLconst [1] (SETBE x)) => (SETA x)
730 (XORLconst [1] (SETA x)) => (SETBE x)
731
732 // Special case for floating point - LF/LEF not generated
733 (NE (TESTB (SETGF cmp) (SETGF cmp)) yes no) => (UGT cmp yes no)
734 (NE (TESTB (SETGEF cmp) (SETGEF cmp)) yes no) => (UGE cmp yes no)
735 (NE (TESTB (SETEQF cmp) (SETEQF cmp)) yes no) => (EQF cmp yes no)
736 (NE (TESTB (SETNEF cmp) (SETNEF cmp)) yes no) => (NEF cmp yes no)
737
738 // Disabled because it interferes with the pattern match above and makes worse code.
739 // (SETNEF x) => (ORQ (SETNE <typ.Int8> x) (SETNAN <typ.Int8> x))
740 // (SETEQF x) => (ANDQ (SETEQ <typ.Int8> x) (SETORD <typ.Int8> x))
741
742 // fold constants into instructions
743 (ADDQ x (MOVQconst <t> [c])) && is32Bit(c) && !t.IsPtr() => (ADDQconst [int32(c)] x)
744 (ADDQ x (MOVLconst [c])) => (ADDQconst [c] x)
745 (ADDL x (MOVLconst [c])) => (ADDLconst [c] x)
746
747 (SUBQ x (MOVQconst [c])) && is32Bit(c) => (SUBQconst x [int32(c)])
748 (SUBQ (MOVQconst [c]) x) && is32Bit(c) => (NEGQ (SUBQconst <v.Type> x [int32(c)]))
749 (SUBL x (MOVLconst [c])) => (SUBLconst x [c])
750 (SUBL (MOVLconst [c]) x) => (NEGL (SUBLconst <v.Type> x [c]))
751
752 (MULQ x (MOVQconst [c])) && is32Bit(c) => (MULQconst [int32(c)] x)
753 (MULL x (MOVLconst [c])) => (MULLconst [c] x)
754
755 (ANDQ x (MOVQconst [c])) && is32Bit(c) => (ANDQconst [int32(c)] x)
756 (ANDL x (MOVLconst [c])) => (ANDLconst [c] x)
757
758 (AND(L|Q)const [c] (AND(L|Q)const [d] x)) => (AND(L|Q)const [c & d] x)
759 (XOR(L|Q)const [c] (XOR(L|Q)const [d] x)) => (XOR(L|Q)const [c ^ d] x)
760 (OR(L|Q)const [c] (OR(L|Q)const [d] x)) => (OR(L|Q)const [c | d] x)
761
762 (MULLconst [c] (MULLconst [d] x)) => (MULLconst [c * d] x)
763 (MULQconst [c] (MULQconst [d] x)) && is32Bit(int64(c)*int64(d)) => (MULQconst [c * d] x)
764
765 (ORQ x (MOVQconst [c])) && is32Bit(c) => (ORQconst [int32(c)] x)
766 (ORQ x (MOVLconst [c])) => (ORQconst [c] x)
767 (ORL x (MOVLconst [c])) => (ORLconst [c] x)
768
769 (XORQ x (MOVQconst [c])) && is32Bit(c) => (XORQconst [int32(c)] x)
770 (XORL x (MOVLconst [c])) => (XORLconst [c] x)
771
772 (SHLQ x (MOV(Q|L)const [c])) => (SHLQconst [int8(c&63)] x)
773 (SHLL x (MOV(Q|L)const [c])) => (SHLLconst [int8(c&31)] x)
774
775 (SHRQ x (MOV(Q|L)const [c])) => (SHRQconst [int8(c&63)] x)
776 (SHRL x (MOV(Q|L)const [c])) => (SHRLconst [int8(c&31)] x)
777 (SHRW x (MOV(Q|L)const [c])) && c&31 < 16 => (SHRWconst [int8(c&31)] x)
778 (SHRW _ (MOV(Q|L)const [c])) && c&31 >= 16 => (MOVLconst [0])
779 (SHRB x (MOV(Q|L)const [c])) && c&31 < 8 => (SHRBconst [int8(c&31)] x)
780 (SHRB _ (MOV(Q|L)const [c])) && c&31 >= 8 => (MOVLconst [0])
781
782 (SARQ x (MOV(Q|L)const [c])) => (SARQconst [int8(c&63)] x)
783 (SARL x (MOV(Q|L)const [c])) => (SARLconst [int8(c&31)] x)
784 (SARW x (MOV(Q|L)const [c])) => (SARWconst [int8(min(int64(c)&31,15))] x)
785 (SARB x (MOV(Q|L)const [c])) => (SARBconst [int8(min(int64(c)&31,7))] x)
786
787 // Operations which don't affect the low 6/5 bits of the shift amount are NOPs.
788 ((SHLQ|SHRQ|SARQ) x (ADDQconst [c] y)) && c & 63 == 0 => ((SHLQ|SHRQ|SARQ) x y)
789 ((SHLQ|SHRQ|SARQ) x (NEGQ <t> (ADDQconst [c] y))) && c & 63 == 0 => ((SHLQ|SHRQ|SARQ) x (NEGQ <t> y))
790 ((SHLQ|SHRQ|SARQ) x (ANDQconst [c] y)) && c & 63 == 63 => ((SHLQ|SHRQ|SARQ) x y)
791 ((SHLQ|SHRQ|SARQ) x (NEGQ <t> (ANDQconst [c] y))) && c & 63 == 63 => ((SHLQ|SHRQ|SARQ) x (NEGQ <t> y))
792
793 ((SHLL|SHRL|SARL) x (ADDQconst [c] y)) && c & 31 == 0 => ((SHLL|SHRL|SARL) x y)
794 ((SHLL|SHRL|SARL) x (NEGQ <t> (ADDQconst [c] y))) && c & 31 == 0 => ((SHLL|SHRL|SARL) x (NEGQ <t> y))
795 ((SHLL|SHRL|SARL) x (ANDQconst [c] y)) && c & 31 == 31 => ((SHLL|SHRL|SARL) x y)
796 ((SHLL|SHRL|SARL) x (NEGQ <t> (ANDQconst [c] y))) && c & 31 == 31 => ((SHLL|SHRL|SARL) x (NEGQ <t> y))
797
798 ((SHLQ|SHRQ|SARQ) x (ADDLconst [c] y)) && c & 63 == 0 => ((SHLQ|SHRQ|SARQ) x y)
799 ((SHLQ|SHRQ|SARQ) x (NEGL <t> (ADDLconst [c] y))) && c & 63 == 0 => ((SHLQ|SHRQ|SARQ) x (NEGL <t> y))
800 ((SHLQ|SHRQ|SARQ) x (ANDLconst [c] y)) && c & 63 == 63 => ((SHLQ|SHRQ|SARQ) x y)
801 ((SHLQ|SHRQ|SARQ) x (NEGL <t> (ANDLconst [c] y))) && c & 63 == 63 => ((SHLQ|SHRQ|SARQ) x (NEGL <t> y))
802
803 ((SHLL|SHRL|SARL) x (ADDLconst [c] y)) && c & 31 == 0 => ((SHLL|SHRL|SARL) x y)
804 ((SHLL|SHRL|SARL) x (NEGL <t> (ADDLconst [c] y))) && c & 31 == 0 => ((SHLL|SHRL|SARL) x (NEGL <t> y))
805 ((SHLL|SHRL|SARL) x (ANDLconst [c] y)) && c & 31 == 31 => ((SHLL|SHRL|SARL) x y)
806 ((SHLL|SHRL|SARL) x (NEGL <t> (ANDLconst [c] y))) && c & 31 == 31 => ((SHLL|SHRL|SARL) x (NEGL <t> y))
807
808 // rotate left negative = rotate right
809 (ROLQ x (NEG(Q|L) y)) => (RORQ x y)
810 (ROLL x (NEG(Q|L) y)) => (RORL x y)
811 (ROLW x (NEG(Q|L) y)) => (RORW x y)
812 (ROLB x (NEG(Q|L) y)) => (RORB x y)
813
814 // rotate right negative = rotate left
815 (RORQ x (NEG(Q|L) y)) => (ROLQ x y)
816 (RORL x (NEG(Q|L) y)) => (ROLL x y)
817 (RORW x (NEG(Q|L) y)) => (ROLW x y)
818 (RORB x (NEG(Q|L) y)) => (ROLB x y)
819
820 // rotate by constants
821 (ROLQ x (MOV(Q|L)const [c])) => (ROLQconst [int8(c&63)] x)
822 (ROLL x (MOV(Q|L)const [c])) => (ROLLconst [int8(c&31)] x)
823 (ROLW x (MOV(Q|L)const [c])) => (ROLWconst [int8(c&15)] x)
824 (ROLB x (MOV(Q|L)const [c])) => (ROLBconst [int8(c&7) ] x)
825
826 (RORQ x (MOV(Q|L)const [c])) => (ROLQconst [int8((-c)&63)] x)
827 (RORL x (MOV(Q|L)const [c])) => (ROLLconst [int8((-c)&31)] x)
828 (RORW x (MOV(Q|L)const [c])) => (ROLWconst [int8((-c)&15)] x)
829 (RORB x (MOV(Q|L)const [c])) => (ROLBconst [int8((-c)&7) ] x)
830
831 // Constant shift simplifications
832 ((SHLQ|SHRQ|SARQ)const x [0]) => x
833 ((SHLL|SHRL|SARL)const x [0]) => x
834 ((SHRW|SARW)const x [0]) => x
835 ((SHRB|SARB)const x [0]) => x
836 ((ROLQ|ROLL|ROLW|ROLB)const x [0]) => x
837
838 // Multi-register shifts
839 (ORQ (SH(R|L)Q lo bits) (SH(L|R)Q hi (NEGQ bits))) => (SH(R|L)DQ lo hi bits)
840 (ORQ (SH(R|L)XQ lo bits) (SH(L|R)XQ hi (NEGQ bits))) => (SH(R|L)DQ lo hi bits)
841
842 // Note: the word and byte shifts keep the low 5 bits (not the low 4 or 3 bits)
843 // because the x86 instructions are defined to use all 5 bits of the shift even
844 // for the small shifts. I don't think we'll ever generate a weird shift (e.g.
845 // (SHRW x (MOVLconst [24])), but just in case.
846
847 (CMPQ x (MOVQconst [c])) && is32Bit(c) => (CMPQconst x [int32(c)])
848 (CMPQ (MOVQconst [c]) x) && is32Bit(c) => (InvertFlags (CMPQconst x [int32(c)]))
849 (CMPL x (MOVLconst [c])) => (CMPLconst x [c])
850 (CMPL (MOVLconst [c]) x) => (InvertFlags (CMPLconst x [c]))
851 (CMPW x (MOVLconst [c])) => (CMPWconst x [int16(c)])
852 (CMPW (MOVLconst [c]) x) => (InvertFlags (CMPWconst x [int16(c)]))
853 (CMPB x (MOVLconst [c])) => (CMPBconst x [int8(c)])
854 (CMPB (MOVLconst [c]) x) => (InvertFlags (CMPBconst x [int8(c)]))
855
856 // Canonicalize the order of arguments to comparisons - helps with CSE.
857 (CMP(Q|L|W|B) x y) && canonLessThan(x,y) => (InvertFlags (CMP(Q|L|W|B) y x))
858
859 // Using MOVZX instead of AND is cheaper.
860 (AND(Q|L)const [ 0xFF] x) => (MOVBQZX x)
861 (AND(Q|L)const [0xFFFF] x) => (MOVWQZX x)
862 // This rule is currently invalid because 0xFFFFFFFF is not representable by a signed int32.
863 // Commenting out for now, because it also can't trigger because of the is32bit guard on the
864 // ANDQconst lowering-rule, above, prevents 0xFFFFFFFF from matching (for the same reason)
865 // Using an alternate form of this rule segfaults some binaries because of
866 // adverse interactions with other passes.
867 // (ANDQconst [0xFFFFFFFF] x) => (MOVLQZX x)
868
869 // strength reduction
870 (MUL(Q|L)const [ 0] _) => (MOV(Q|L)const [0])
871 (MUL(Q|L)const [ 1] x) => x
872 (MULQconst [c] x) && canMulStrengthReduce(config, int64(c)) => {mulStrengthReduce(v, x, int64(c))}
873 (MULLconst [c] x) && v.Type.Size() <= 4 && canMulStrengthReduce32(config, c) => {mulStrengthReduce32(v, x, c)}
874
875 // Prefer addition when shifting left by one
876 (SHL(Q|L)const [1] x) => (ADD(Q|L) x x)
877
878 // combine add/shift into LEAQ/LEAL
879 (ADD(L|Q) x (SHL(L|Q)const [3] y)) => (LEA(L|Q)8 x y)
880 (ADD(L|Q) x (SHL(L|Q)const [2] y)) => (LEA(L|Q)4 x y)
881 (ADD(L|Q) x (ADD(L|Q) y y)) => (LEA(L|Q)2 x y)
882 (ADD(L|Q) x (ADD(L|Q) x y)) => (LEA(L|Q)2 y x)
883
884 // combine ADDQ/ADDQconst into LEAQ1/LEAL1
885 (ADD(Q|L)const [c] (ADD(Q|L) x y)) => (LEA(Q|L)1 [c] x y)
886 (ADD(Q|L) (ADD(Q|L)const [c] x) y) => (LEA(Q|L)1 [c] x y)
887 (ADD(Q|L)const [c] (ADD(Q|L) x x)) => (LEA(Q|L)1 [c] x x)
888
889 // fold ADDQ/ADDL into LEAQ/LEAL
890 (ADD(Q|L)const [c] (LEA(Q|L) [d] {s} x)) && is32Bit(int64(c)+int64(d)) => (LEA(Q|L) [c+d] {s} x)
891 (LEA(Q|L) [c] {s} (ADD(Q|L)const [d] x)) && is32Bit(int64(c)+int64(d)) => (LEA(Q|L) [c+d] {s} x)
892 (LEA(Q|L) [c] {s} (ADD(Q|L) x y)) && x.Op != OpSB && y.Op != OpSB => (LEA(Q|L)1 [c] {s} x y)
893 (ADD(Q|L) x (LEA(Q|L) [c] {s} y)) && x.Op != OpSB && y.Op != OpSB => (LEA(Q|L)1 [c] {s} x y)
894
895 // fold ADDQconst/ADDLconst into LEAQx/LEALx
896 (ADD(Q|L)const [c] (LEA(Q|L)1 [d] {s} x y)) && is32Bit(int64(c)+int64(d)) => (LEA(Q|L)1 [c+d] {s} x y)
897 (ADD(Q|L)const [c] (LEA(Q|L)2 [d] {s} x y)) && is32Bit(int64(c)+int64(d)) => (LEA(Q|L)2 [c+d] {s} x y)
898 (ADD(Q|L)const [c] (LEA(Q|L)4 [d] {s} x y)) && is32Bit(int64(c)+int64(d)) => (LEA(Q|L)4 [c+d] {s} x y)
899 (ADD(Q|L)const [c] (LEA(Q|L)8 [d] {s} x y)) && is32Bit(int64(c)+int64(d)) => (LEA(Q|L)8 [c+d] {s} x y)
900 (LEA(Q|L)1 [c] {s} (ADD(Q|L)const [d] x) y) && is32Bit(int64(c)+int64(d)) && x.Op != OpSB => (LEA(Q|L)1 [c+d] {s} x y)
901 (LEA(Q|L)2 [c] {s} (ADD(Q|L)const [d] x) y) && is32Bit(int64(c)+int64(d)) && x.Op != OpSB => (LEA(Q|L)2 [c+d] {s} x y)
902 (LEA(Q|L)2 [c] {s} x (ADD(Q|L)const [d] y)) && is32Bit(int64(c)+2*int64(d)) && y.Op != OpSB => (LEA(Q|L)2 [c+2*d] {s} x y)
903 (LEA(Q|L)4 [c] {s} (ADD(Q|L)const [d] x) y) && is32Bit(int64(c)+int64(d)) && x.Op != OpSB => (LEA(Q|L)4 [c+d] {s} x y)
904 (LEA(Q|L)4 [c] {s} x (ADD(Q|L)const [d] y)) && is32Bit(int64(c)+4*int64(d)) && y.Op != OpSB => (LEA(Q|L)4 [c+4*d] {s} x y)
905 (LEA(Q|L)8 [c] {s} (ADD(Q|L)const [d] x) y) && is32Bit(int64(c)+int64(d)) && x.Op != OpSB => (LEA(Q|L)8 [c+d] {s} x y)
906 (LEA(Q|L)8 [c] {s} x (ADD(Q|L)const [d] y)) && is32Bit(int64(c)+8*int64(d)) && y.Op != OpSB => (LEA(Q|L)8 [c+8*d] {s} x y)
907
908 // fold shifts into LEAQx/LEALx
909 (LEA(Q|L)1 [c] {s} x z:(ADD(Q|L) y y)) && x != z => (LEA(Q|L)2 [c] {s} x y)
910 (LEA(Q|L)1 [c] {s} x (SHL(Q|L)const [2] y)) => (LEA(Q|L)4 [c] {s} x y)
911 (LEA(Q|L)1 [c] {s} x (SHL(Q|L)const [3] y)) => (LEA(Q|L)8 [c] {s} x y)
912 (LEA(Q|L)2 [c] {s} x z:(ADD(Q|L) y y)) && x != z => (LEA(Q|L)4 [c] {s} x y)
913 (LEA(Q|L)2 [c] {s} x (SHL(Q|L)const [2] y)) => (LEA(Q|L)8 [c] {s} x y)
914 (LEA(Q|L)4 [c] {s} x z:(ADD(Q|L) y y)) && x != z => (LEA(Q|L)8 [c] {s} x y)
915
916 // (x + x) << 1 -> x << 2
917 (LEA(Q|L)2 [0] {s} (ADD(Q|L) x x) x) && s == nil => (SHL(Q|L)const [2] x)
918
919 // (x + x) << 2 -> x << 3 and similar
920 (SHL(Q|L)const [c] (ADD(Q|L) x x)) => (SHL(Q|L)const [c+1] x)
921
922 // reverse ordering of compare instruction
923 (SETL (InvertFlags x)) => (SETG x)
924 (SETG (InvertFlags x)) => (SETL x)
925 (SETB (InvertFlags x)) => (SETA x)
926 (SETA (InvertFlags x)) => (SETB x)
927 (SETLE (InvertFlags x)) => (SETGE x)
928 (SETGE (InvertFlags x)) => (SETLE x)
929 (SETBE (InvertFlags x)) => (SETAE x)
930 (SETAE (InvertFlags x)) => (SETBE x)
931 (SETEQ (InvertFlags x)) => (SETEQ x)
932 (SETNE (InvertFlags x)) => (SETNE x)
933
934 (SETLstore [off] {sym} ptr (InvertFlags x) mem) => (SETGstore [off] {sym} ptr x mem)
935 (SETGstore [off] {sym} ptr (InvertFlags x) mem) => (SETLstore [off] {sym} ptr x mem)
936 (SETBstore [off] {sym} ptr (InvertFlags x) mem) => (SETAstore [off] {sym} ptr x mem)
937 (SETAstore [off] {sym} ptr (InvertFlags x) mem) => (SETBstore [off] {sym} ptr x mem)
938 (SETLEstore [off] {sym} ptr (InvertFlags x) mem) => (SETGEstore [off] {sym} ptr x mem)
939 (SETGEstore [off] {sym} ptr (InvertFlags x) mem) => (SETLEstore [off] {sym} ptr x mem)
940 (SETBEstore [off] {sym} ptr (InvertFlags x) mem) => (SETAEstore [off] {sym} ptr x mem)
941 (SETAEstore [off] {sym} ptr (InvertFlags x) mem) => (SETBEstore [off] {sym} ptr x mem)
942 (SETEQstore [off] {sym} ptr (InvertFlags x) mem) => (SETEQstore [off] {sym} ptr x mem)
943 (SETNEstore [off] {sym} ptr (InvertFlags x) mem) => (SETNEstore [off] {sym} ptr x mem)
944
945 // sign extended loads
946 // Note: The combined instruction must end up in the same block
947 // as the original load. If not, we end up making a value with
948 // memory type live in two different blocks, which can lead to
949 // multiple memory values alive simultaneously.
950 // Make sure we don't combine these ops if the load has another use.
951 // This prevents a single load from being split into multiple loads
952 // which then might return different values. See test/atomicload.go.
953 (MOVBQSX x:(MOVBload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVBQSXload <v.Type> [off] {sym} ptr mem)
954 (MOVBQSX x:(MOVWload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVBQSXload <v.Type> [off] {sym} ptr mem)
955 (MOVBQSX x:(MOVLload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVBQSXload <v.Type> [off] {sym} ptr mem)
956 (MOVBQSX x:(MOVQload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVBQSXload <v.Type> [off] {sym} ptr mem)
957 (MOVBQZX x:(MOVBload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVBload <v.Type> [off] {sym} ptr mem)
958 (MOVBQZX x:(MOVWload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVBload <v.Type> [off] {sym} ptr mem)
959 (MOVBQZX x:(MOVLload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVBload <v.Type> [off] {sym} ptr mem)
960 (MOVBQZX x:(MOVQload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVBload <v.Type> [off] {sym} ptr mem)
961 (MOVWQSX x:(MOVWload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVWQSXload <v.Type> [off] {sym} ptr mem)
962 (MOVWQSX x:(MOVLload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVWQSXload <v.Type> [off] {sym} ptr mem)
963 (MOVWQSX x:(MOVQload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVWQSXload <v.Type> [off] {sym} ptr mem)
964 (MOVWQZX x:(MOVWload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVWload <v.Type> [off] {sym} ptr mem)
965 (MOVWQZX x:(MOVLload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVWload <v.Type> [off] {sym} ptr mem)
966 (MOVWQZX x:(MOVQload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVWload <v.Type> [off] {sym} ptr mem)
967 (MOVLQSX x:(MOVLload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVLQSXload <v.Type> [off] {sym} ptr mem)
968 (MOVLQSX x:(MOVQload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVLQSXload <v.Type> [off] {sym} ptr mem)
969 (MOVLQZX x:(MOVLload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVLload <v.Type> [off] {sym} ptr mem)
970 (MOVLQZX x:(MOVQload [off] {sym} ptr mem)) && x.Uses == 1 && clobber(x) => @x.Block (MOVLload <v.Type> [off] {sym} ptr mem)
971
972 // replace load from same location as preceding store with zero/sign extension (or copy in case of full width)
973 (MOVBload [off] {sym} ptr (MOVBstore [off2] {sym2} ptr2 x _)) && sym == sym2 && off == off2 && isSamePtr(ptr, ptr2) => (MOVBQZX x)
974 (MOVWload [off] {sym} ptr (MOVWstore [off2] {sym2} ptr2 x _)) && sym == sym2 && off == off2 && isSamePtr(ptr, ptr2) => (MOVWQZX x)
975 (MOVLload [off] {sym} ptr (MOVLstore [off2] {sym2} ptr2 x _)) && sym == sym2 && off == off2 && isSamePtr(ptr, ptr2) => (MOVLQZX x)
976 (MOVQload [off] {sym} ptr (MOVQstore [off2] {sym2} ptr2 x _)) && sym == sym2 && off == off2 && isSamePtr(ptr, ptr2) => x
977 (MOVBQSXload [off] {sym} ptr (MOVBstore [off2] {sym2} ptr2 x _)) && sym == sym2 && off == off2 && isSamePtr(ptr, ptr2) => (MOVBQSX x)
978 (MOVWQSXload [off] {sym} ptr (MOVWstore [off2] {sym2} ptr2 x _)) && sym == sym2 && off == off2 && isSamePtr(ptr, ptr2) => (MOVWQSX x)
979 (MOVLQSXload [off] {sym} ptr (MOVLstore [off2] {sym2} ptr2 x _)) && sym == sym2 && off == off2 && isSamePtr(ptr, ptr2) => (MOVLQSX x)
980
981 // Fold extensions and ANDs together.
982 (MOVBQZX (ANDLconst [c] x)) => (ANDLconst [c & 0xff] x)
983 (MOVWQZX (ANDLconst [c] x)) => (ANDLconst [c & 0xffff] x)
984 (MOVLQZX (ANDLconst [c] x)) => (ANDLconst [c] x)
985 (MOVBQSX (ANDLconst [c] x)) && c & 0x80 == 0 => (ANDLconst [c & 0x7f] x)
986 (MOVWQSX (ANDLconst [c] x)) && c & 0x8000 == 0 => (ANDLconst [c & 0x7fff] x)
987 (MOVLQSX (ANDLconst [c] x)) && uint32(c) & 0x80000000 == 0 => (ANDLconst [c & 0x7fffffff] x)
988
989 // Don't extend before storing
990 (MOVLstore [off] {sym} ptr (MOVLQSX x) mem) => (MOVLstore [off] {sym} ptr x mem)
991 (MOVWstore [off] {sym} ptr (MOVWQSX x) mem) => (MOVWstore [off] {sym} ptr x mem)
992 (MOVBstore [off] {sym} ptr (MOVBQSX x) mem) => (MOVBstore [off] {sym} ptr x mem)
993 (MOVLstore [off] {sym} ptr (MOVLQZX x) mem) => (MOVLstore [off] {sym} ptr x mem)
994 (MOVWstore [off] {sym} ptr (MOVWQZX x) mem) => (MOVWstore [off] {sym} ptr x mem)
995 (MOVBstore [off] {sym} ptr (MOVBQZX x) mem) => (MOVBstore [off] {sym} ptr x mem)
996
997 // fold constants into memory operations
998 // Note that this is not always a good idea because if not all the uses of
999 // the ADDQconst get eliminated, we still have to compute the ADDQconst and we now
1000 // have potentially two live values (ptr and (ADDQconst [off] ptr)) instead of one.
1001 // Nevertheless, let's do it!
1002 (MOV(Q|L|W|B|SS|SD|O)load [off1] {sym} (ADDQconst [off2] ptr) mem) && is32Bit(int64(off1)+int64(off2)) =>
1003 (MOV(Q|L|W|B|SS|SD|O)load [off1+off2] {sym} ptr mem)
1004 (MOV(Q|L|W|B|SS|SD|O)store [off1] {sym} (ADDQconst [off2] ptr) val mem) && is32Bit(int64(off1)+int64(off2)) =>
1005 (MOV(Q|L|W|B|SS|SD|O)store [off1+off2] {sym} ptr val mem)
1006 (SET(L|G|B|A|LE|GE|BE|AE|EQ|NE)store [off1] {sym} (ADDQconst [off2] base) val mem) && is32Bit(int64(off1)+int64(off2)) =>
1007 (SET(L|G|B|A|LE|GE|BE|AE|EQ|NE)store [off1+off2] {sym} base val mem)
1008 ((ADD|SUB|AND|OR|XOR)Qload [off1] {sym} val (ADDQconst [off2] base) mem) && is32Bit(int64(off1)+int64(off2)) =>
1009 ((ADD|SUB|AND|OR|XOR)Qload [off1+off2] {sym} val base mem)
1010 ((ADD|SUB|AND|OR|XOR)Lload [off1] {sym} val (ADDQconst [off2] base) mem) && is32Bit(int64(off1)+int64(off2)) =>
1011 ((ADD|SUB|AND|OR|XOR)Lload [off1+off2] {sym} val base mem)
1012 (CMP(Q|L|W|B)load [off1] {sym} (ADDQconst [off2] base) val mem) && is32Bit(int64(off1)+int64(off2)) =>
1013 (CMP(Q|L|W|B)load [off1+off2] {sym} base val mem)
1014 (CMP(Q|L|W|B)constload [valoff1] {sym} (ADDQconst [off2] base) mem) && ValAndOff(valoff1).canAdd32(off2) =>
1015 (CMP(Q|L|W|B)constload [ValAndOff(valoff1).addOffset32(off2)] {sym} base mem)
1016
1017 ((ADD|SUB|MUL|DIV)SSload [off1] {sym} val (ADDQconst [off2] base) mem) && is32Bit(int64(off1)+int64(off2)) =>
1018 ((ADD|SUB|MUL|DIV)SSload [off1+off2] {sym} val base mem)
1019 ((ADD|SUB|MUL|DIV)SDload [off1] {sym} val (ADDQconst [off2] base) mem) && is32Bit(int64(off1)+int64(off2)) =>
1020 ((ADD|SUB|MUL|DIV)SDload [off1+off2] {sym} val base mem)
1021 ((ADD|AND|OR|XOR)Qconstmodify [valoff1] {sym} (ADDQconst [off2] base) mem) && ValAndOff(valoff1).canAdd32(off2) =>
1022 ((ADD|AND|OR|XOR)Qconstmodify [ValAndOff(valoff1).addOffset32(off2)] {sym} base mem)
1023 ((ADD|AND|OR|XOR)Lconstmodify [valoff1] {sym} (ADDQconst [off2] base) mem) && ValAndOff(valoff1).canAdd32(off2) =>
1024 ((ADD|AND|OR|XOR)Lconstmodify [ValAndOff(valoff1).addOffset32(off2)] {sym} base mem)
1025 ((ADD|SUB|AND|OR|XOR)Qmodify [off1] {sym} (ADDQconst [off2] base) val mem) && is32Bit(int64(off1)+int64(off2)) =>
1026 ((ADD|SUB|AND|OR|XOR)Qmodify [off1+off2] {sym} base val mem)
1027 ((ADD|SUB|AND|OR|XOR)Lmodify [off1] {sym} (ADDQconst [off2] base) val mem) && is32Bit(int64(off1)+int64(off2)) =>
1028 ((ADD|SUB|AND|OR|XOR)Lmodify [off1+off2] {sym} base val mem)
1029
1030 // Fold constants into stores.
1031 (MOVQstore [off] {sym} ptr (MOVQconst [c]) mem) && validVal(c) =>
1032 (MOVQstoreconst [makeValAndOff(int32(c),off)] {sym} ptr mem)
1033 (MOVLstore [off] {sym} ptr (MOV(L|Q)const [c]) mem) =>
1034 (MOVLstoreconst [makeValAndOff(int32(c),off)] {sym} ptr mem)
1035 (MOVWstore [off] {sym} ptr (MOV(L|Q)const [c]) mem) =>
1036 (MOVWstoreconst [makeValAndOff(int32(int16(c)),off)] {sym} ptr mem)
1037 (MOVBstore [off] {sym} ptr (MOV(L|Q)const [c]) mem) =>
1038 (MOVBstoreconst [makeValAndOff(int32(int8(c)),off)] {sym} ptr mem)
1039
1040 // Fold address offsets into constant stores.
1041 (MOV(Q|L|W|B|O)storeconst [sc] {s} (ADDQconst [off] ptr) mem) && ValAndOff(sc).canAdd32(off) =>
1042 (MOV(Q|L|W|B|O)storeconst [ValAndOff(sc).addOffset32(off)] {s} ptr mem)
1043
1044 // We need to fold LEAQ into the MOVx ops so that the live variable analysis knows
1045 // what variables are being read/written by the ops.
1046 (MOV(Q|L|W|B|SS|SD|O|BQSX|WQSX|LQSX)load [off1] {sym1} (LEAQ [off2] {sym2} base) mem)
1047 && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1048 (MOV(Q|L|W|B|SS|SD|O|BQSX|WQSX|LQSX)load [off1+off2] {mergeSym(sym1,sym2)} base mem)
1049 (MOV(Q|L|W|B|SS|SD|O)store [off1] {sym1} (LEAQ [off2] {sym2} base) val mem)
1050 && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1051 (MOV(Q|L|W|B|SS|SD|O)store [off1+off2] {mergeSym(sym1,sym2)} base val mem)
1052 (MOV(Q|L|W|B|O)storeconst [sc] {sym1} (LEAQ [off] {sym2} ptr) mem) && canMergeSym(sym1, sym2) && ValAndOff(sc).canAdd32(off) =>
1053 (MOV(Q|L|W|B|O)storeconst [ValAndOff(sc).addOffset32(off)] {mergeSym(sym1, sym2)} ptr mem)
1054 (SET(L|G|B|A|LE|GE|BE|AE|EQ|NE)store [off1] {sym1} (LEAQ [off2] {sym2} base) val mem)
1055 && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1056 (SET(L|G|B|A|LE|GE|BE|AE|EQ|NE)store [off1+off2] {mergeSym(sym1,sym2)} base val mem)
1057 ((ADD|SUB|AND|OR|XOR)Qload [off1] {sym1} val (LEAQ [off2] {sym2} base) mem)
1058 && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1059 ((ADD|SUB|AND|OR|XOR)Qload [off1+off2] {mergeSym(sym1,sym2)} val base mem)
1060 ((ADD|SUB|AND|OR|XOR)Lload [off1] {sym1} val (LEAQ [off2] {sym2} base) mem)
1061 && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1062 ((ADD|SUB|AND|OR|XOR)Lload [off1+off2] {mergeSym(sym1,sym2)} val base mem)
1063 (CMP(Q|L|W|B)load [off1] {sym1} (LEAQ [off2] {sym2} base) val mem)
1064 && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1065 (CMP(Q|L|W|B)load [off1+off2] {mergeSym(sym1,sym2)} base val mem)
1066 (CMP(Q|L|W|B)constload [valoff1] {sym1} (LEAQ [off2] {sym2} base) mem)
1067 && ValAndOff(valoff1).canAdd32(off2) && canMergeSym(sym1, sym2) =>
1068 (CMP(Q|L|W|B)constload [ValAndOff(valoff1).addOffset32(off2)] {mergeSym(sym1,sym2)} base mem)
1069
1070 ((ADD|SUB|MUL|DIV)SSload [off1] {sym1} val (LEAQ [off2] {sym2} base) mem)
1071 && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1072 ((ADD|SUB|MUL|DIV)SSload [off1+off2] {mergeSym(sym1,sym2)} val base mem)
1073 ((ADD|SUB|MUL|DIV)SDload [off1] {sym1} val (LEAQ [off2] {sym2} base) mem)
1074 && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1075 ((ADD|SUB|MUL|DIV)SDload [off1+off2] {mergeSym(sym1,sym2)} val base mem)
1076 ((ADD|AND|OR|XOR)Qconstmodify [valoff1] {sym1} (LEAQ [off2] {sym2} base) mem)
1077 && ValAndOff(valoff1).canAdd32(off2) && canMergeSym(sym1, sym2) =>
1078 ((ADD|AND|OR|XOR)Qconstmodify [ValAndOff(valoff1).addOffset32(off2)] {mergeSym(sym1,sym2)} base mem)
1079 ((ADD|AND|OR|XOR)Lconstmodify [valoff1] {sym1} (LEAQ [off2] {sym2} base) mem)
1080 && ValAndOff(valoff1).canAdd32(off2) && canMergeSym(sym1, sym2) =>
1081 ((ADD|AND|OR|XOR)Lconstmodify [ValAndOff(valoff1).addOffset32(off2)] {mergeSym(sym1,sym2)} base mem)
1082 ((ADD|SUB|AND|OR|XOR)Qmodify [off1] {sym1} (LEAQ [off2] {sym2} base) val mem)
1083 && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1084 ((ADD|SUB|AND|OR|XOR)Qmodify [off1+off2] {mergeSym(sym1,sym2)} base val mem)
1085 ((ADD|SUB|AND|OR|XOR)Lmodify [off1] {sym1} (LEAQ [off2] {sym2} base) val mem)
1086 && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1087 ((ADD|SUB|AND|OR|XOR)Lmodify [off1+off2] {mergeSym(sym1,sym2)} base val mem)
1088
1089 // fold LEAQs together
1090 (LEAQ [off1] {sym1} (LEAQ [off2] {sym2} x)) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1091 (LEAQ [off1+off2] {mergeSym(sym1,sym2)} x)
1092
1093 // LEAQ into LEAQ1
1094 (LEAQ1 [off1] {sym1} (LEAQ [off2] {sym2} x) y) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) && x.Op != OpSB =>
1095 (LEAQ1 [off1+off2] {mergeSym(sym1,sym2)} x y)
1096
1097 // LEAQ1 into LEAQ
1098 (LEAQ [off1] {sym1} (LEAQ1 [off2] {sym2} x y)) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1099 (LEAQ1 [off1+off2] {mergeSym(sym1,sym2)} x y)
1100
1101 // LEAQ into LEAQ[248]
1102 (LEAQ2 [off1] {sym1} (LEAQ [off2] {sym2} x) y) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) && x.Op != OpSB =>
1103 (LEAQ2 [off1+off2] {mergeSym(sym1,sym2)} x y)
1104 (LEAQ4 [off1] {sym1} (LEAQ [off2] {sym2} x) y) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) && x.Op != OpSB =>
1105 (LEAQ4 [off1+off2] {mergeSym(sym1,sym2)} x y)
1106 (LEAQ8 [off1] {sym1} (LEAQ [off2] {sym2} x) y) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) && x.Op != OpSB =>
1107 (LEAQ8 [off1+off2] {mergeSym(sym1,sym2)} x y)
1108
1109 // LEAQ[248] into LEAQ
1110 (LEAQ [off1] {sym1} (LEAQ2 [off2] {sym2} x y)) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1111 (LEAQ2 [off1+off2] {mergeSym(sym1,sym2)} x y)
1112 (LEAQ [off1] {sym1} (LEAQ4 [off2] {sym2} x y)) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1113 (LEAQ4 [off1+off2] {mergeSym(sym1,sym2)} x y)
1114 (LEAQ [off1] {sym1} (LEAQ8 [off2] {sym2} x y)) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1115 (LEAQ8 [off1+off2] {mergeSym(sym1,sym2)} x y)
1116
1117 // LEAQ[1248] into LEAQ[1248]. Only some such merges are possible.
1118 (LEAQ1 [off1] {sym1} x (LEAQ1 [off2] {sym2} y y)) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1119 (LEAQ2 [off1+off2] {mergeSym(sym1, sym2)} x y)
1120 (LEAQ1 [off1] {sym1} x (LEAQ1 [off2] {sym2} x y)) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1121 (LEAQ2 [off1+off2] {mergeSym(sym1, sym2)} y x)
1122 (LEAQ2 [off1] {sym1} x (LEAQ1 [off2] {sym2} y y)) && is32Bit(int64(off1)+2*int64(off2)) && sym2 == nil =>
1123 (LEAQ4 [off1+2*off2] {sym1} x y)
1124 (LEAQ4 [off1] {sym1} x (LEAQ1 [off2] {sym2} y y)) && is32Bit(int64(off1)+4*int64(off2)) && sym2 == nil =>
1125 (LEAQ8 [off1+4*off2] {sym1} x y)
1126 // TODO: more?
1127
1128 // Lower LEAQ2/4/8 when the offset is a constant
1129 (LEAQ2 [off] {sym} x (MOV(Q|L)const [scale])) && is32Bit(int64(off)+int64(scale)*2) =>
1130 (LEAQ [off+int32(scale)*2] {sym} x)
1131 (LEAQ4 [off] {sym} x (MOV(Q|L)const [scale])) && is32Bit(int64(off)+int64(scale)*4) =>
1132 (LEAQ [off+int32(scale)*4] {sym} x)
1133 (LEAQ8 [off] {sym} x (MOV(Q|L)const [scale])) && is32Bit(int64(off)+int64(scale)*8) =>
1134 (LEAQ [off+int32(scale)*8] {sym} x)
1135
1136 // Absorb InvertFlags into branches.
1137 (LT (InvertFlags cmp) yes no) => (GT cmp yes no)
1138 (GT (InvertFlags cmp) yes no) => (LT cmp yes no)
1139 (LE (InvertFlags cmp) yes no) => (GE cmp yes no)
1140 (GE (InvertFlags cmp) yes no) => (LE cmp yes no)
1141 (ULT (InvertFlags cmp) yes no) => (UGT cmp yes no)
1142 (UGT (InvertFlags cmp) yes no) => (ULT cmp yes no)
1143 (ULE (InvertFlags cmp) yes no) => (UGE cmp yes no)
1144 (UGE (InvertFlags cmp) yes no) => (ULE cmp yes no)
1145 (EQ (InvertFlags cmp) yes no) => (EQ cmp yes no)
1146 (NE (InvertFlags cmp) yes no) => (NE cmp yes no)
1147
1148 // Constant comparisons.
1149 (CMPQconst (MOVQconst [x]) [y]) && x==int64(y) => (FlagEQ)
1150 (CMPQconst (MOVQconst [x]) [y]) && x<int64(y) && uint64(x)<uint64(int64(y)) => (FlagLT_ULT)
1151 (CMPQconst (MOVQconst [x]) [y]) && x<int64(y) && uint64(x)>uint64(int64(y)) => (FlagLT_UGT)
1152 (CMPQconst (MOVQconst [x]) [y]) && x>int64(y) && uint64(x)<uint64(int64(y)) => (FlagGT_ULT)
1153 (CMPQconst (MOVQconst [x]) [y]) && x>int64(y) && uint64(x)>uint64(int64(y)) => (FlagGT_UGT)
1154 (CMPLconst (MOVLconst [x]) [y]) && x==y => (FlagEQ)
1155 (CMPLconst (MOVLconst [x]) [y]) && x<y && uint32(x)<uint32(y) => (FlagLT_ULT)
1156 (CMPLconst (MOVLconst [x]) [y]) && x<y && uint32(x)>uint32(y) => (FlagLT_UGT)
1157 (CMPLconst (MOVLconst [x]) [y]) && x>y && uint32(x)<uint32(y) => (FlagGT_ULT)
1158 (CMPLconst (MOVLconst [x]) [y]) && x>y && uint32(x)>uint32(y) => (FlagGT_UGT)
1159 (CMPWconst (MOVLconst [x]) [y]) && int16(x)==y => (FlagEQ)
1160 (CMPWconst (MOVLconst [x]) [y]) && int16(x)<y && uint16(x)<uint16(y) => (FlagLT_ULT)
1161 (CMPWconst (MOVLconst [x]) [y]) && int16(x)<y && uint16(x)>uint16(y) => (FlagLT_UGT)
1162 (CMPWconst (MOVLconst [x]) [y]) && int16(x)>y && uint16(x)<uint16(y) => (FlagGT_ULT)
1163 (CMPWconst (MOVLconst [x]) [y]) && int16(x)>y && uint16(x)>uint16(y) => (FlagGT_UGT)
1164 (CMPBconst (MOVLconst [x]) [y]) && int8(x)==y => (FlagEQ)
1165 (CMPBconst (MOVLconst [x]) [y]) && int8(x)<y && uint8(x)<uint8(y) => (FlagLT_ULT)
1166 (CMPBconst (MOVLconst [x]) [y]) && int8(x)<y && uint8(x)>uint8(y) => (FlagLT_UGT)
1167 (CMPBconst (MOVLconst [x]) [y]) && int8(x)>y && uint8(x)<uint8(y) => (FlagGT_ULT)
1168 (CMPBconst (MOVLconst [x]) [y]) && int8(x)>y && uint8(x)>uint8(y) => (FlagGT_UGT)
1169
1170 // CMPQconst requires a 32 bit const, but we can still constant-fold 64 bit consts.
1171 // In theory this applies to any of the simplifications above,
1172 // but CMPQ is the only one I've actually seen occur.
1173 (CMPQ (MOVQconst [x]) (MOVQconst [y])) && x==y => (FlagEQ)
1174 (CMPQ (MOVQconst [x]) (MOVQconst [y])) && x<y && uint64(x)<uint64(y) => (FlagLT_ULT)
1175 (CMPQ (MOVQconst [x]) (MOVQconst [y])) && x<y && uint64(x)>uint64(y) => (FlagLT_UGT)
1176 (CMPQ (MOVQconst [x]) (MOVQconst [y])) && x>y && uint64(x)<uint64(y) => (FlagGT_ULT)
1177 (CMPQ (MOVQconst [x]) (MOVQconst [y])) && x>y && uint64(x)>uint64(y) => (FlagGT_UGT)
1178
1179 // Other known comparisons.
1180 (CMPQconst (MOVBQZX _) [c]) && 0xFF < c => (FlagLT_ULT)
1181 (CMPQconst (MOVWQZX _) [c]) && 0xFFFF < c => (FlagLT_ULT)
1182 (CMPLconst (SHRLconst _ [c]) [n]) && 0 <= n && 0 < c && c <= 32 && (1<<uint64(32-c)) <= uint64(n) => (FlagLT_ULT)
1183 (CMPQconst (SHRQconst _ [c]) [n]) && 0 <= n && 0 < c && c <= 64 && (1<<uint64(64-c)) <= uint64(n) => (FlagLT_ULT)
1184 (CMPQconst (ANDQconst _ [m]) [n]) && 0 <= m && m < n => (FlagLT_ULT)
1185 (CMPQconst (ANDLconst _ [m]) [n]) && 0 <= m && m < n => (FlagLT_ULT)
1186 (CMPLconst (ANDLconst _ [m]) [n]) && 0 <= m && m < n => (FlagLT_ULT)
1187 (CMPWconst (ANDLconst _ [m]) [n]) && 0 <= int16(m) && int16(m) < n => (FlagLT_ULT)
1188 (CMPBconst (ANDLconst _ [m]) [n]) && 0 <= int8(m) && int8(m) < n => (FlagLT_ULT)
1189
1190 // TESTQ c c sets flags like CMPQ c 0.
1191 (TESTQconst [c] (MOVQconst [d])) && int64(c) == d && c == 0 => (FlagEQ)
1192 (TESTLconst [c] (MOVLconst [c])) && c == 0 => (FlagEQ)
1193 (TESTQconst [c] (MOVQconst [d])) && int64(c) == d && c < 0 => (FlagLT_UGT)
1194 (TESTLconst [c] (MOVLconst [c])) && c < 0 => (FlagLT_UGT)
1195 (TESTQconst [c] (MOVQconst [d])) && int64(c) == d && c > 0 => (FlagGT_UGT)
1196 (TESTLconst [c] (MOVLconst [c])) && c > 0 => (FlagGT_UGT)
1197
1198 // TODO: DIVxU also.
1199
1200 // Absorb flag constants into SBB ops.
1201 (SBBQcarrymask (FlagEQ)) => (MOVQconst [0])
1202 (SBBQcarrymask (FlagLT_ULT)) => (MOVQconst [-1])
1203 (SBBQcarrymask (FlagLT_UGT)) => (MOVQconst [0])
1204 (SBBQcarrymask (FlagGT_ULT)) => (MOVQconst [-1])
1205 (SBBQcarrymask (FlagGT_UGT)) => (MOVQconst [0])
1206 (SBBLcarrymask (FlagEQ)) => (MOVLconst [0])
1207 (SBBLcarrymask (FlagLT_ULT)) => (MOVLconst [-1])
1208 (SBBLcarrymask (FlagLT_UGT)) => (MOVLconst [0])
1209 (SBBLcarrymask (FlagGT_ULT)) => (MOVLconst [-1])
1210 (SBBLcarrymask (FlagGT_UGT)) => (MOVLconst [0])
1211
1212 // Absorb flag constants into branches.
1213 ((EQ|LE|GE|ULE|UGE) (FlagEQ) yes no) => (First yes no)
1214 ((NE|LT|GT|ULT|UGT) (FlagEQ) yes no) => (First no yes)
1215 ((NE|LT|LE|ULT|ULE) (FlagLT_ULT) yes no) => (First yes no)
1216 ((EQ|GT|GE|UGT|UGE) (FlagLT_ULT) yes no) => (First no yes)
1217 ((NE|LT|LE|UGT|UGE) (FlagLT_UGT) yes no) => (First yes no)
1218 ((EQ|GT|GE|ULT|ULE) (FlagLT_UGT) yes no) => (First no yes)
1219 ((NE|GT|GE|ULT|ULE) (FlagGT_ULT) yes no) => (First yes no)
1220 ((EQ|LT|LE|UGT|UGE) (FlagGT_ULT) yes no) => (First no yes)
1221 ((NE|GT|GE|UGT|UGE) (FlagGT_UGT) yes no) => (First yes no)
1222 ((EQ|LT|LE|ULT|ULE) (FlagGT_UGT) yes no) => (First no yes)
1223
1224 // Absorb flag constants into SETxx ops.
1225 ((SETEQ|SETLE|SETGE|SETBE|SETAE) (FlagEQ)) => (MOVLconst [1])
1226 ((SETNE|SETL|SETG|SETB|SETA) (FlagEQ)) => (MOVLconst [0])
1227 ((SETNE|SETL|SETLE|SETB|SETBE) (FlagLT_ULT)) => (MOVLconst [1])
1228 ((SETEQ|SETG|SETGE|SETA|SETAE) (FlagLT_ULT)) => (MOVLconst [0])
1229 ((SETNE|SETL|SETLE|SETA|SETAE) (FlagLT_UGT)) => (MOVLconst [1])
1230 ((SETEQ|SETG|SETGE|SETB|SETBE) (FlagLT_UGT)) => (MOVLconst [0])
1231 ((SETNE|SETG|SETGE|SETB|SETBE) (FlagGT_ULT)) => (MOVLconst [1])
1232 ((SETEQ|SETL|SETLE|SETA|SETAE) (FlagGT_ULT)) => (MOVLconst [0])
1233 ((SETNE|SETG|SETGE|SETA|SETAE) (FlagGT_UGT)) => (MOVLconst [1])
1234 ((SETEQ|SETL|SETLE|SETB|SETBE) (FlagGT_UGT)) => (MOVLconst [0])
1235
1236 (SETEQstore [off] {sym} ptr (FlagEQ) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1237 (SETEQstore [off] {sym} ptr (FlagLT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1238 (SETEQstore [off] {sym} ptr (FlagLT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1239 (SETEQstore [off] {sym} ptr (FlagGT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1240 (SETEQstore [off] {sym} ptr (FlagGT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1241
1242 (SETNEstore [off] {sym} ptr (FlagEQ) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1243 (SETNEstore [off] {sym} ptr (FlagLT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1244 (SETNEstore [off] {sym} ptr (FlagLT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1245 (SETNEstore [off] {sym} ptr (FlagGT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1246 (SETNEstore [off] {sym} ptr (FlagGT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1247
1248 (SETLstore [off] {sym} ptr (FlagEQ) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1249 (SETLstore [off] {sym} ptr (FlagLT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1250 (SETLstore [off] {sym} ptr (FlagLT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1251 (SETLstore [off] {sym} ptr (FlagGT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1252 (SETLstore [off] {sym} ptr (FlagGT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1253
1254 (SETLEstore [off] {sym} ptr (FlagEQ) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1255 (SETLEstore [off] {sym} ptr (FlagLT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1256 (SETLEstore [off] {sym} ptr (FlagLT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1257 (SETLEstore [off] {sym} ptr (FlagGT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1258 (SETLEstore [off] {sym} ptr (FlagGT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1259
1260 (SETGstore [off] {sym} ptr (FlagEQ) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1261 (SETGstore [off] {sym} ptr (FlagLT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1262 (SETGstore [off] {sym} ptr (FlagLT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1263 (SETGstore [off] {sym} ptr (FlagGT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1264 (SETGstore [off] {sym} ptr (FlagGT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1265
1266 (SETGEstore [off] {sym} ptr (FlagEQ) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1267 (SETGEstore [off] {sym} ptr (FlagLT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1268 (SETGEstore [off] {sym} ptr (FlagLT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1269 (SETGEstore [off] {sym} ptr (FlagGT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1270 (SETGEstore [off] {sym} ptr (FlagGT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1271
1272 (SETBstore [off] {sym} ptr (FlagEQ) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1273 (SETBstore [off] {sym} ptr (FlagLT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1274 (SETBstore [off] {sym} ptr (FlagLT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1275 (SETBstore [off] {sym} ptr (FlagGT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1276 (SETBstore [off] {sym} ptr (FlagGT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1277
1278 (SETBEstore [off] {sym} ptr (FlagEQ) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1279 (SETBEstore [off] {sym} ptr (FlagLT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1280 (SETBEstore [off] {sym} ptr (FlagLT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1281 (SETBEstore [off] {sym} ptr (FlagGT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1282 (SETBEstore [off] {sym} ptr (FlagGT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1283
1284 (SETAstore [off] {sym} ptr (FlagEQ) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1285 (SETAstore [off] {sym} ptr (FlagLT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1286 (SETAstore [off] {sym} ptr (FlagLT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1287 (SETAstore [off] {sym} ptr (FlagGT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1288 (SETAstore [off] {sym} ptr (FlagGT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1289
1290 (SETAEstore [off] {sym} ptr (FlagEQ) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1291 (SETAEstore [off] {sym} ptr (FlagLT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1292 (SETAEstore [off] {sym} ptr (FlagLT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1293 (SETAEstore [off] {sym} ptr (FlagGT_ULT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [0]) mem)
1294 (SETAEstore [off] {sym} ptr (FlagGT_UGT) mem) => (MOVBstore [off] {sym} ptr (MOVLconst <typ.UInt8> [1]) mem)
1295
1296 // Remove redundant *const ops
1297 (ADDQconst [0] x) => x
1298 (ADDLconst [c] x) && c==0 => x
1299 (SUBQconst [0] x) => x
1300 (SUBLconst [c] x) && c==0 => x
1301 (ANDQconst [0] _) => (MOVQconst [0])
1302 (ANDLconst [c] _) && c==0 => (MOVLconst [0])
1303 (ANDQconst [-1] x) => x
1304 (ANDLconst [c] x) && c==-1 => x
1305 (ORQconst [0] x) => x
1306 (ORLconst [c] x) && c==0 => x
1307 (ORQconst [-1] _) => (MOVQconst [-1])
1308 (ORLconst [c] _) && c==-1 => (MOVLconst [-1])
1309 (XORQconst [0] x) => x
1310 (XORLconst [c] x) && c==0 => x
1311 // TODO: since we got rid of the W/B versions, we might miss
1312 // things like (ANDLconst [0x100] x) which were formerly
1313 // (ANDBconst [0] x). Probably doesn't happen very often.
1314 // If we cared, we might do:
1315 // (ANDLconst <t> [c] x) && t.Size()==1 && int8(x)==0 -> (MOVLconst [0])
1316
1317 // Remove redundant ops
1318 // Not in generic rules, because they may appear after lowering e. g. Slicemask
1319 (NEG(Q|L) (NEG(Q|L) x)) => x
1320 (NEG(Q|L) s:(SUB(Q|L) x y)) && s.Uses == 1 => (SUB(Q|L) y x)
1321
1322 // Convert constant subtracts to constant adds
1323 (SUBQconst [c] x) && c != -(1<<31) => (ADDQconst [-c] x)
1324 (SUBLconst [c] x) => (ADDLconst [-c] x)
1325
1326 // generic constant folding
1327 // TODO: more of this
1328 (ADDQconst [c] (MOVQconst [d])) => (MOVQconst [int64(c)+d])
1329 (ADDLconst [c] (MOVLconst [d])) => (MOVLconst [c+d])
1330 (ADDQconst [c] (ADDQconst [d] x)) && is32Bit(int64(c)+int64(d)) => (ADDQconst [c+d] x)
1331 (ADDLconst [c] (ADDLconst [d] x)) => (ADDLconst [c+d] x)
1332 (SUBQconst (MOVQconst [d]) [c]) => (MOVQconst [d-int64(c)])
1333 (SUBQconst (SUBQconst x [d]) [c]) && is32Bit(int64(-c)-int64(d)) => (ADDQconst [-c-d] x)
1334 (SARQconst [c] (MOVQconst [d])) => (MOVQconst [d>>uint64(c)])
1335 (SARLconst [c] (MOVQconst [d])) => (MOVQconst [int64(int32(d))>>uint64(c)])
1336 (SARWconst [c] (MOVQconst [d])) => (MOVQconst [int64(int16(d))>>uint64(c)])
1337 (SARBconst [c] (MOVQconst [d])) => (MOVQconst [int64(int8(d))>>uint64(c)])
1338 (NEGQ (MOVQconst [c])) => (MOVQconst [-c])
1339 (NEGL (MOVLconst [c])) => (MOVLconst [-c])
1340 (MULQconst [c] (MOVQconst [d])) => (MOVQconst [int64(c)*d])
1341 (MULLconst [c] (MOVLconst [d])) => (MOVLconst [c*d])
1342 (ANDQconst [c] (MOVQconst [d])) => (MOVQconst [int64(c)&d])
1343 (ANDLconst [c] (MOVLconst [d])) => (MOVLconst [c&d])
1344 (ORQconst [c] (MOVQconst [d])) => (MOVQconst [int64(c)|d])
1345 (ORLconst [c] (MOVLconst [d])) => (MOVLconst [c|d])
1346 (XORQconst [c] (MOVQconst [d])) => (MOVQconst [int64(c)^d])
1347 (XORLconst [c] (MOVLconst [d])) => (MOVLconst [c^d])
1348 (NOTQ (MOVQconst [c])) => (MOVQconst [^c])
1349 (NOTL (MOVLconst [c])) => (MOVLconst [^c])
1350 (BTSQconst [c] (MOVQconst [d])) => (MOVQconst [d|(1<<uint32(c))])
1351 (BTRQconst [c] (MOVQconst [d])) => (MOVQconst [d&^(1<<uint32(c))])
1352 (BTCQconst [c] (MOVQconst [d])) => (MOVQconst [d^(1<<uint32(c))])
1353
1354 // If c or d doesn't fit into 32 bits, then we can't construct ORQconst,
1355 // but we can still constant-fold.
1356 // In theory this applies to any of the simplifications above,
1357 // but ORQ is the only one I've actually seen occur.
1358 (ORQ (MOVQconst [c]) (MOVQconst [d])) => (MOVQconst [c|d])
1359
1360 // generic simplifications
1361 // TODO: more of this
1362 (ADDQ x (NEGQ y)) => (SUBQ x y)
1363 (ADDL x (NEGL y)) => (SUBL x y)
1364 (SUBQ x x) => (MOVQconst [0])
1365 (SUBL x x) => (MOVLconst [0])
1366 (ANDQ x x) => x
1367 (ANDL x x) => x
1368 (ORQ x x) => x
1369 (ORL x x) => x
1370 (XORQ x x) => (MOVQconst [0])
1371 (XORL x x) => (MOVLconst [0])
1372
1373 (SHLLconst [d] (MOVLconst [c])) => (MOVLconst [c << uint64(d)])
1374 (SHLQconst [d] (MOVQconst [c])) => (MOVQconst [c << uint64(d)])
1375 (SHLQconst [d] (MOVLconst [c])) => (MOVQconst [int64(c) << uint64(d)])
1376
1377 // Fold NEG into ADDconst/MULconst. Take care to keep c in 32 bit range.
1378 (NEGQ (ADDQconst [c] (NEGQ x))) && c != -(1<<31) => (ADDQconst [-c] x)
1379 (MULQconst [c] (NEGQ x)) && c != -(1<<31) => (MULQconst [-c] x)
1380
1381 // checking AND against 0.
1382 (CMPQconst a:(ANDQ x y) [0]) && a.Uses == 1 => (TESTQ x y)
1383 (CMPLconst a:(ANDL x y) [0]) && a.Uses == 1 => (TESTL x y)
1384 (CMPWconst a:(ANDL x y) [0]) && a.Uses == 1 => (TESTW x y)
1385 (CMPBconst a:(ANDL x y) [0]) && a.Uses == 1 => (TESTB x y)
1386 (CMPQconst a:(ANDQconst [c] x) [0]) && a.Uses == 1 => (TESTQconst [c] x)
1387 (CMPLconst a:(ANDLconst [c] x) [0]) && a.Uses == 1 => (TESTLconst [c] x)
1388 (CMPWconst a:(ANDLconst [c] x) [0]) && a.Uses == 1 => (TESTWconst [int16(c)] x)
1389 (CMPBconst a:(ANDLconst [c] x) [0]) && a.Uses == 1 => (TESTBconst [int8(c)] x)
1390
1391 // Convert TESTx to TESTxconst if possible.
1392 (TESTQ (MOVQconst [c]) x) && is32Bit(c) => (TESTQconst [int32(c)] x)
1393 (TESTL (MOVLconst [c]) x) => (TESTLconst [c] x)
1394 (TESTW (MOVLconst [c]) x) => (TESTWconst [int16(c)] x)
1395 (TESTB (MOVLconst [c]) x) => (TESTBconst [int8(c)] x)
1396
1397 // TEST %reg,%reg is shorter than CMP
1398 (CMPQconst x [0]) => (TESTQ x x)
1399 (CMPLconst x [0]) => (TESTL x x)
1400 (CMPWconst x [0]) => (TESTW x x)
1401 (CMPBconst x [0]) => (TESTB x x)
1402 (TESTQconst [-1] x) && x.Op != OpAMD64MOVQconst => (TESTQ x x)
1403 (TESTLconst [-1] x) && x.Op != OpAMD64MOVLconst => (TESTL x x)
1404 (TESTWconst [-1] x) && x.Op != OpAMD64MOVLconst => (TESTW x x)
1405 (TESTBconst [-1] x) && x.Op != OpAMD64MOVLconst => (TESTB x x)
1406
1407 // Convert LEAQ1 back to ADDQ if we can
1408 (LEAQ1 [0] x y) && v.Aux == nil => (ADDQ x y)
1409
1410 (MOVQstoreconst [c] {s} p1 x:(MOVQstoreconst [a] {s} p0 mem))
1411 && x.Uses == 1
1412 && sequentialAddresses(p0, p1, int64(a.Off()+8-c.Off()))
1413 && a.Val() == 0
1414 && c.Val() == 0
1415 && setPos(v, x.Pos)
1416 && clobber(x)
1417 => (MOVOstoreconst [makeValAndOff(0,a.Off())] {s} p0 mem)
1418 (MOVQstoreconst [a] {s} p0 x:(MOVQstoreconst [c] {s} p1 mem))
1419 && x.Uses == 1
1420 && sequentialAddresses(p0, p1, int64(a.Off()+8-c.Off()))
1421 && a.Val() == 0
1422 && c.Val() == 0
1423 && setPos(v, x.Pos)
1424 && clobber(x)
1425 => (MOVOstoreconst [makeValAndOff(0,a.Off())] {s} p0 mem)
1426
1427 // Merge load and op
1428 // TODO: add indexed variants?
1429 ((ADD|SUB|AND|OR|XOR)Q x l:(MOVQload [off] {sym} ptr mem)) && canMergeLoadClobber(v, l, x) && clobber(l) => ((ADD|SUB|AND|OR|XOR)Qload x [off] {sym} ptr mem)
1430 ((ADD|SUB|AND|OR|XOR)L x l:(MOVLload [off] {sym} ptr mem)) && canMergeLoadClobber(v, l, x) && clobber(l) => ((ADD|SUB|AND|OR|XOR)Lload x [off] {sym} ptr mem)
1431 ((ADD|SUB|MUL|DIV)SD x l:(MOVSDload [off] {sym} ptr mem)) && canMergeLoadClobber(v, l, x) && clobber(l) => ((ADD|SUB|MUL|DIV)SDload x [off] {sym} ptr mem)
1432 ((ADD|SUB|MUL|DIV)SS x l:(MOVSSload [off] {sym} ptr mem)) && canMergeLoadClobber(v, l, x) && clobber(l) => ((ADD|SUB|MUL|DIV)SSload x [off] {sym} ptr mem)
1433 (MOVLstore {sym} [off] ptr y:((ADD|AND|OR|XOR)Lload x [off] {sym} ptr mem) mem) && y.Uses==1 && clobber(y) => ((ADD|AND|OR|XOR)Lmodify [off] {sym} ptr x mem)
1434 (MOVLstore {sym} [off] ptr y:((ADD|SUB|AND|OR|XOR)L l:(MOVLload [off] {sym} ptr mem) x) mem) && y.Uses==1 && l.Uses==1 && clobber(y, l) =>
1435 ((ADD|SUB|AND|OR|XOR)Lmodify [off] {sym} ptr x mem)
1436 (MOVQstore {sym} [off] ptr y:((ADD|AND|OR|XOR)Qload x [off] {sym} ptr mem) mem) && y.Uses==1 && clobber(y) => ((ADD|AND|OR|XOR)Qmodify [off] {sym} ptr x mem)
1437 (MOVQstore {sym} [off] ptr y:((ADD|SUB|AND|OR|XOR)Q l:(MOVQload [off] {sym} ptr mem) x) mem) && y.Uses==1 && l.Uses==1 && clobber(y, l) =>
1438 ((ADD|SUB|AND|OR|XOR)Qmodify [off] {sym} ptr x mem)
1439 (MOVQstore {sym} [off] ptr x:(BT(S|R|C)Qconst [c] l:(MOVQload {sym} [off] ptr mem)) mem) && x.Uses == 1 && l.Uses == 1 && clobber(x, l) =>
1440 (BT(S|R|C)Qconstmodify {sym} [makeValAndOff(int32(c),off)] ptr mem)
1441
1442 // Merge ADDQconst and LEAQ into atomic loads.
1443 (MOV(Q|L|B)atomicload [off1] {sym} (ADDQconst [off2] ptr) mem) && is32Bit(int64(off1)+int64(off2)) =>
1444 (MOV(Q|L|B)atomicload [off1+off2] {sym} ptr mem)
1445 (MOV(Q|L|B)atomicload [off1] {sym1} (LEAQ [off2] {sym2} ptr) mem) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) =>
1446 (MOV(Q|L|B)atomicload [off1+off2] {mergeSym(sym1, sym2)} ptr mem)
1447
1448 // Merge ADDQconst and LEAQ into atomic stores.
1449 (XCHGQ [off1] {sym} val (ADDQconst [off2] ptr) mem) && is32Bit(int64(off1)+int64(off2)) =>
1450 (XCHGQ [off1+off2] {sym} val ptr mem)
1451 (XCHGQ [off1] {sym1} val (LEAQ [off2] {sym2} ptr) mem) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) && ptr.Op != OpSB =>
1452 (XCHGQ [off1+off2] {mergeSym(sym1,sym2)} val ptr mem)
1453 (XCHGL [off1] {sym} val (ADDQconst [off2] ptr) mem) && is32Bit(int64(off1)+int64(off2)) =>
1454 (XCHGL [off1+off2] {sym} val ptr mem)
1455 (XCHGL [off1] {sym1} val (LEAQ [off2] {sym2} ptr) mem) && is32Bit(int64(off1)+int64(off2)) && canMergeSym(sym1, sym2) && ptr.Op != OpSB =>
1456 (XCHGL [off1+off2] {mergeSym(sym1,sym2)} val ptr mem)
1457
1458 // Merge ADDQconst into atomic adds.
1459 // TODO: merging LEAQ doesn't work, assembler doesn't like the resulting instructions.
1460 (XADDQlock [off1] {sym} val (ADDQconst [off2] ptr) mem) && is32Bit(int64(off1)+int64(off2)) =>
1461 (XADDQlock [off1+off2] {sym} val ptr mem)
1462 (XADDLlock [off1] {sym} val (ADDQconst [off2] ptr) mem) && is32Bit(int64(off1)+int64(off2)) =>
1463 (XADDLlock [off1+off2] {sym} val ptr mem)
1464
1465 // Merge ADDQconst into atomic compare and swaps.
1466 // TODO: merging LEAQ doesn't work, assembler doesn't like the resulting instructions.
1467 (CMPXCHGQlock [off1] {sym} (ADDQconst [off2] ptr) old new_ mem) && is32Bit(int64(off1)+int64(off2)) =>
1468 (CMPXCHGQlock [off1+off2] {sym} ptr old new_ mem)
1469 (CMPXCHGLlock [off1] {sym} (ADDQconst [off2] ptr) old new_ mem) && is32Bit(int64(off1)+int64(off2)) =>
1470 (CMPXCHGLlock [off1+off2] {sym} ptr old new_ mem)
1471
1472 // We don't need the conditional move if we know the arg of BSF is not zero.
1473 (CMOVQEQ x _ (Select1 (BS(F|R)Q (ORQconst [c] _)))) && c != 0 => x
1474 // Extension is unnecessary for trailing zeros.
1475 (BSFQ (ORQconst <t> [1<<8] (MOVBQZX x))) => (BSFQ (ORQconst <t> [1<<8] x))
1476 (BSFQ (ORQconst <t> [1<<16] (MOVWQZX x))) => (BSFQ (ORQconst <t> [1<<16] x))
1477
1478 // Redundant sign/zero extensions
1479 // Note: see issue 21963. We have to make sure we use the right type on
1480 // the resulting extension (the outer type, not the inner type).
1481 (MOVLQSX (MOVLQSX x)) => (MOVLQSX x)
1482 (MOVLQSX (MOVWQSX x)) => (MOVWQSX x)
1483 (MOVLQSX (MOVBQSX x)) => (MOVBQSX x)
1484 (MOVWQSX (MOVWQSX x)) => (MOVWQSX x)
1485 (MOVWQSX (MOVBQSX x)) => (MOVBQSX x)
1486 (MOVBQSX (MOVBQSX x)) => (MOVBQSX x)
1487 (MOVLQZX (MOVLQZX x)) => (MOVLQZX x)
1488 (MOVLQZX (MOVWQZX x)) => (MOVWQZX x)
1489 (MOVLQZX (MOVBQZX x)) => (MOVBQZX x)
1490 (MOVWQZX (MOVWQZX x)) => (MOVWQZX x)
1491 (MOVWQZX (MOVBQZX x)) => (MOVBQZX x)
1492 (MOVBQZX (MOVBQZX x)) => (MOVBQZX x)
1493
1494 (MOVQstore [off] {sym} ptr a:((ADD|AND|OR|XOR)Qconst [c] l:(MOVQload [off] {sym} ptr2 mem)) mem)
1495 && isSamePtr(ptr, ptr2) && a.Uses == 1 && l.Uses == 1 && clobber(l, a) =>
1496 ((ADD|AND|OR|XOR)Qconstmodify {sym} [makeValAndOff(int32(c),off)] ptr mem)
1497 (MOVLstore [off] {sym} ptr a:((ADD|AND|OR|XOR)Lconst [c] l:(MOVLload [off] {sym} ptr2 mem)) mem)
1498 && isSamePtr(ptr, ptr2) && a.Uses == 1 && l.Uses == 1 && clobber(l, a) =>
1499 ((ADD|AND|OR|XOR)Lconstmodify {sym} [makeValAndOff(int32(c),off)] ptr mem)
1500
1501 // float <-> int register moves, with no conversion.
1502 // These come up when compiling math.{Float{32,64}bits,Float{32,64}frombits}.
1503 (MOVQload [off] {sym} ptr (MOVSDstore [off] {sym} ptr val _)) => (MOVQf2i val)
1504 (MOVLload [off] {sym} ptr (MOVSSstore [off] {sym} ptr val _)) => (MOVLf2i val)
1505 (MOVSDload [off] {sym} ptr (MOVQstore [off] {sym} ptr val _)) => (MOVQi2f val)
1506 (MOVSSload [off] {sym} ptr (MOVLstore [off] {sym} ptr val _)) => (MOVLi2f val)
1507
1508 // Other load-like ops.
1509 (ADDQload x [off] {sym} ptr (MOVSDstore [off] {sym} ptr y _)) => (ADDQ x (MOVQf2i y))
1510 (ADDLload x [off] {sym} ptr (MOVSSstore [off] {sym} ptr y _)) => (ADDL x (MOVLf2i y))
1511 (SUBQload x [off] {sym} ptr (MOVSDstore [off] {sym} ptr y _)) => (SUBQ x (MOVQf2i y))
1512 (SUBLload x [off] {sym} ptr (MOVSSstore [off] {sym} ptr y _)) => (SUBL x (MOVLf2i y))
1513 (ANDQload x [off] {sym} ptr (MOVSDstore [off] {sym} ptr y _)) => (ANDQ x (MOVQf2i y))
1514 (ANDLload x [off] {sym} ptr (MOVSSstore [off] {sym} ptr y _)) => (ANDL x (MOVLf2i y))
1515 ( ORQload x [off] {sym} ptr (MOVSDstore [off] {sym} ptr y _)) => ( ORQ x (MOVQf2i y))
1516 ( ORLload x [off] {sym} ptr (MOVSSstore [off] {sym} ptr y _)) => ( ORL x (MOVLf2i y))
1517 (XORQload x [off] {sym} ptr (MOVSDstore [off] {sym} ptr y _)) => (XORQ x (MOVQf2i y))
1518 (XORLload x [off] {sym} ptr (MOVSSstore [off] {sym} ptr y _)) => (XORL x (MOVLf2i y))
1519
1520 (ADDSDload x [off] {sym} ptr (MOVQstore [off] {sym} ptr y _)) => (ADDSD x (MOVQi2f y))
1521 (ADDSSload x [off] {sym} ptr (MOVLstore [off] {sym} ptr y _)) => (ADDSS x (MOVLi2f y))
1522 (SUBSDload x [off] {sym} ptr (MOVQstore [off] {sym} ptr y _)) => (SUBSD x (MOVQi2f y))
1523 (SUBSSload x [off] {sym} ptr (MOVLstore [off] {sym} ptr y _)) => (SUBSS x (MOVLi2f y))
1524 (MULSDload x [off] {sym} ptr (MOVQstore [off] {sym} ptr y _)) => (MULSD x (MOVQi2f y))
1525 (MULSSload x [off] {sym} ptr (MOVLstore [off] {sym} ptr y _)) => (MULSS x (MOVLi2f y))
1526
1527 // Detect FMA
1528 (ADDS(S|D) (MULS(S|D) x y) z) && buildcfg.GOAMD64 >= 3 && z.Block.Func.useFMA(v) => (VFMADD231S(S|D) z x y)
1529
1530 // Redirect stores to use the other register set.
1531 (MOVQstore [off] {sym} ptr (MOVQf2i val) mem) => (MOVSDstore [off] {sym} ptr val mem)
1532 (MOVLstore [off] {sym} ptr (MOVLf2i val) mem) => (MOVSSstore [off] {sym} ptr val mem)
1533 (MOVSDstore [off] {sym} ptr (MOVQi2f val) mem) => (MOVQstore [off] {sym} ptr val mem)
1534 (MOVSSstore [off] {sym} ptr (MOVLi2f val) mem) => (MOVLstore [off] {sym} ptr val mem)
1535
1536 (MOVSDstore [off] {sym} ptr (MOVSDconst [f]) mem) && f == f => (MOVQstore [off] {sym} ptr (MOVQconst [int64(math.Float64bits(f))]) mem)
1537 (MOVSSstore [off] {sym} ptr (MOVSSconst [f]) mem) && f == f => (MOVLstore [off] {sym} ptr (MOVLconst [int32(math.Float32bits(f))]) mem)
1538
1539 // Load args directly into the register class where it will be used.
1540 // We do this by just modifying the type of the Arg.
1541 (MOVQf2i <t> (Arg <u> [off] {sym})) && t.Size() == u.Size() => @b.Func.Entry (Arg <t> [off] {sym})
1542 (MOVLf2i <t> (Arg <u> [off] {sym})) && t.Size() == u.Size() => @b.Func.Entry (Arg <t> [off] {sym})
1543 (MOVQi2f <t> (Arg <u> [off] {sym})) && t.Size() == u.Size() => @b.Func.Entry (Arg <t> [off] {sym})
1544 (MOVLi2f <t> (Arg <u> [off] {sym})) && t.Size() == u.Size() => @b.Func.Entry (Arg <t> [off] {sym})
1545
1546 // LEAQ is rematerializeable, so this helps to avoid register spill.
1547 // See issue 22947 for details
1548 (ADD(Q|L)const [off] x:(SP)) => (LEA(Q|L) [off] x)
1549
1550 // HMULx is commutative, but its first argument must go in AX.
1551 // If possible, put a rematerializeable value in the first argument slot,
1552 // to reduce the odds that another value will be have to spilled
1553 // specifically to free up AX.
1554 (HMUL(Q|L) x y) && !x.rematerializeable() && y.rematerializeable() => (HMUL(Q|L) y x)
1555 (HMUL(Q|L)U x y) && !x.rematerializeable() && y.rematerializeable() => (HMUL(Q|L)U y x)
1556
1557 // Fold loads into compares
1558 // Note: these may be undone by the flagalloc pass.
1559 (CMP(Q|L|W|B) l:(MOV(Q|L|W|B)load {sym} [off] ptr mem) x) && canMergeLoad(v, l) && clobber(l) => (CMP(Q|L|W|B)load {sym} [off] ptr x mem)
1560 (CMP(Q|L|W|B) x l:(MOV(Q|L|W|B)load {sym} [off] ptr mem)) && canMergeLoad(v, l) && clobber(l) => (InvertFlags (CMP(Q|L|W|B)load {sym} [off] ptr x mem))
1561
1562 (CMP(Q|L)const l:(MOV(Q|L)load {sym} [off] ptr mem) [c])
1563 && l.Uses == 1
1564 && clobber(l) =>
1565 @l.Block (CMP(Q|L)constload {sym} [makeValAndOff(c,off)] ptr mem)
1566 (CMP(W|B)const l:(MOV(W|B)load {sym} [off] ptr mem) [c])
1567 && l.Uses == 1
1568 && clobber(l) =>
1569 @l.Block (CMP(W|B)constload {sym} [makeValAndOff(int32(c),off)] ptr mem)
1570
1571 (CMPQload {sym} [off] ptr (MOVQconst [c]) mem) && validVal(c) => (CMPQconstload {sym} [makeValAndOff(int32(c),off)] ptr mem)
1572 (CMPLload {sym} [off] ptr (MOVLconst [c]) mem) => (CMPLconstload {sym} [makeValAndOff(c,off)] ptr mem)
1573 (CMPWload {sym} [off] ptr (MOVLconst [c]) mem) => (CMPWconstload {sym} [makeValAndOff(int32(int16(c)),off)] ptr mem)
1574 (CMPBload {sym} [off] ptr (MOVLconst [c]) mem) => (CMPBconstload {sym} [makeValAndOff(int32(int8(c)),off)] ptr mem)
1575
1576 (TEST(Q|L|W|B) l:(MOV(Q|L|W|B)load {sym} [off] ptr mem) l2)
1577 && l == l2
1578 && l.Uses == 2
1579 && clobber(l) =>
1580 @l.Block (CMP(Q|L|W|B)constload {sym} [makeValAndOff(0, off)] ptr mem)
1581
1582 // Convert ANDload to MOVload when we can do the AND in a containing TEST op.
1583 // Only do when it's within the same block, so we don't have flags live across basic block boundaries.
1584 // See issue 44228.
1585 (TEST(Q|L) a:(AND(Q|L)load [off] {sym} x ptr mem) a) && a.Uses == 2 && a.Block == v.Block && clobber(a) => (TEST(Q|L) (MOV(Q|L)load <a.Type> [off] {sym} ptr mem) x)
1586
1587 (MOVBload [off] {sym} (SB) _) && symIsRO(sym) => (MOVLconst [int32(read8(sym, int64(off)))])
1588 (MOVWload [off] {sym} (SB) _) && symIsRO(sym) => (MOVLconst [int32(read16(sym, int64(off), config.ctxt.Arch.ByteOrder))])
1589 (MOVLload [off] {sym} (SB) _) && symIsRO(sym) => (MOVLconst [int32(read32(sym, int64(off), config.ctxt.Arch.ByteOrder))])
1590 (MOVQload [off] {sym} (SB) _) && symIsRO(sym) => (MOVQconst [int64(read64(sym, int64(off), config.ctxt.Arch.ByteOrder))])
1591 (MOVBQSXload [off] {sym} (SB) _) && symIsRO(sym) => (MOVQconst [int64(int8(read8(sym, int64(off))))])
1592 (MOVWQSXload [off] {sym} (SB) _) && symIsRO(sym) => (MOVQconst [int64(int16(read16(sym, int64(off), config.ctxt.Arch.ByteOrder)))])
1593 (MOVLQSXload [off] {sym} (SB) _) && symIsRO(sym) => (MOVQconst [int64(int32(read32(sym, int64(off), config.ctxt.Arch.ByteOrder)))])
1594
1595
1596 (MOVOstore [dstOff] {dstSym} ptr (MOVOload [srcOff] {srcSym} (SB) _) mem) && symIsRO(srcSym) =>
1597 (MOVQstore [dstOff+8] {dstSym} ptr (MOVQconst [int64(read64(srcSym, int64(srcOff)+8, config.ctxt.Arch.ByteOrder))])
1598 (MOVQstore [dstOff] {dstSym} ptr (MOVQconst [int64(read64(srcSym, int64(srcOff), config.ctxt.Arch.ByteOrder))]) mem))
1599
1600 // Arch-specific inlining for small or disjoint runtime.memmove
1601 // Match post-lowering calls, memory version.
1602 (SelectN [0] call:(CALLstatic {sym} s1:(MOVQstoreconst _ [sc] s2:(MOVQstore _ src s3:(MOVQstore _ dst mem)))))
1603 && sc.Val64() >= 0
1604 && isSameCall(sym, "runtime.memmove")
1605 && s1.Uses == 1 && s2.Uses == 1 && s3.Uses == 1
1606 && isInlinableMemmove(dst, src, sc.Val64(), config)
1607 && clobber(s1, s2, s3, call)
1608 => (Move [sc.Val64()] dst src mem)
1609
1610 // Match post-lowering calls, register version.
1611 (SelectN [0] call:(CALLstatic {sym} dst src (MOVQconst [sz]) mem))
1612 && sz >= 0
1613 && isSameCall(sym, "runtime.memmove")
1614 && call.Uses == 1
1615 && isInlinableMemmove(dst, src, sz, config)
1616 && clobber(call)
1617 => (Move [sz] dst src mem)
1618
1619 // Prefetch instructions
1620 (PrefetchCache ...) => (PrefetchT0 ...)
1621 (PrefetchCacheStreamed ...) => (PrefetchNTA ...)
1622
1623 // CPUID feature: BMI1.
1624 (AND(Q|L) x (NOT(Q|L) y)) && buildcfg.GOAMD64 >= 3 => (ANDN(Q|L) x y)
1625 (AND(Q|L) x (NEG(Q|L) x)) && buildcfg.GOAMD64 >= 3 => (BLSI(Q|L) x)
1626 (XOR(Q|L) x (ADD(Q|L)const [-1] x)) && buildcfg.GOAMD64 >= 3 => (BLSMSK(Q|L) x)
1627 (AND(Q|L) <t> x (ADD(Q|L)const [-1] x)) && buildcfg.GOAMD64 >= 3 => (Select0 <t> (BLSR(Q|L) x))
1628 // eliminate TEST instruction in classical "isPowerOfTwo" check
1629 (SETEQ (TEST(Q|L) s:(Select0 blsr:(BLSR(Q|L) _)) s)) => (SETEQ (Select1 <types.TypeFlags> blsr))
1630 (CMOVQEQ x y (TEST(Q|L) s:(Select0 blsr:(BLSR(Q|L) _)) s)) => (CMOVQEQ x y (Select1 <types.TypeFlags> blsr))
1631 (CMOVLEQ x y (TEST(Q|L) s:(Select0 blsr:(BLSR(Q|L) _)) s)) => (CMOVLEQ x y (Select1 <types.TypeFlags> blsr))
1632 (EQ (TEST(Q|L) s:(Select0 blsr:(BLSR(Q|L) _)) s) yes no) => (EQ (Select1 <types.TypeFlags> blsr) yes no)
1633 (SETNE (TEST(Q|L) s:(Select0 blsr:(BLSR(Q|L) _)) s)) => (SETNE (Select1 <types.TypeFlags> blsr))
1634 (CMOVQNE x y (TEST(Q|L) s:(Select0 blsr:(BLSR(Q|L) _)) s)) => (CMOVQNE x y (Select1 <types.TypeFlags> blsr))
1635 (CMOVLNE x y (TEST(Q|L) s:(Select0 blsr:(BLSR(Q|L) _)) s)) => (CMOVLNE x y (Select1 <types.TypeFlags> blsr))
1636 (NE (TEST(Q|L) s:(Select0 blsr:(BLSR(Q|L) _)) s) yes no) => (NE (Select1 <types.TypeFlags> blsr) yes no)
1637
1638 (BSWAP(Q|L) (BSWAP(Q|L) p)) => p
1639
1640 // CPUID feature: MOVBE.
1641 (MOV(Q|L)store [i] {s} p x:(BSWAP(Q|L) w) mem) && x.Uses == 1 && buildcfg.GOAMD64 >= 3 => (MOVBE(Q|L)store [i] {s} p w mem)
1642 (MOVBE(Q|L)store [i] {s} p x:(BSWAP(Q|L) w) mem) && x.Uses == 1 => (MOV(Q|L)store [i] {s} p w mem)
1643 (BSWAP(Q|L) x:(MOV(Q|L)load [i] {s} p mem)) && x.Uses == 1 && buildcfg.GOAMD64 >= 3 => @x.Block (MOVBE(Q|L)load [i] {s} p mem)
1644 (BSWAP(Q|L) x:(MOVBE(Q|L)load [i] {s} p mem)) && x.Uses == 1 => @x.Block (MOV(Q|L)load [i] {s} p mem)
1645 (MOVWstore [i] {s} p x:(ROLWconst [8] w) mem) && x.Uses == 1 && buildcfg.GOAMD64 >= 3 => (MOVBEWstore [i] {s} p w mem)
1646 (MOVBEWstore [i] {s} p x:(ROLWconst [8] w) mem) && x.Uses == 1 => (MOVWstore [i] {s} p w mem)
1647
1648 (SAR(Q|L) l:(MOV(Q|L)load [off] {sym} ptr mem) x) && buildcfg.GOAMD64 >= 3 && canMergeLoad(v, l) && clobber(l) => (SARX(Q|L)load [off] {sym} ptr x mem)
1649 (SHL(Q|L) l:(MOV(Q|L)load [off] {sym} ptr mem) x) && buildcfg.GOAMD64 >= 3 && canMergeLoad(v, l) && clobber(l) => (SHLX(Q|L)load [off] {sym} ptr x mem)
1650 (SHR(Q|L) l:(MOV(Q|L)load [off] {sym} ptr mem) x) && buildcfg.GOAMD64 >= 3 && canMergeLoad(v, l) && clobber(l) => (SHRX(Q|L)load [off] {sym} ptr x mem)
1651
1652 ((SHL|SHR|SAR)XQload [off] {sym} ptr (MOVQconst [c]) mem) => ((SHL|SHR|SAR)Qconst [int8(c&63)] (MOVQload [off] {sym} ptr mem))
1653 ((SHL|SHR|SAR)XQload [off] {sym} ptr (MOVLconst [c]) mem) => ((SHL|SHR|SAR)Qconst [int8(c&63)] (MOVQload [off] {sym} ptr mem))
1654 ((SHL|SHR|SAR)XLload [off] {sym} ptr (MOVLconst [c]) mem) => ((SHL|SHR|SAR)Lconst [int8(c&31)] (MOVLload [off] {sym} ptr mem))
1655
1656 // Convert atomic logical operations to easier ones if we don't use the result.
1657 (Select1 a:(LoweredAtomic(And64|And32|Or64|Or32) ptr val mem)) && a.Uses == 1 && clobber(a) => ((ANDQ|ANDL|ORQ|ORL)lock ptr val mem)
1658
1659 // If we are checking the results of an add, use the flags directly from the add.
1660 // Note that this only works for EQ/NE. ADD sets the CF/OF flags differently
1661 // than TEST sets them.
1662 // Note also that a.Args[0] here refers to the post-flagify'd value.
1663 ((EQ|NE) t:(TESTQ a:(ADDQconst [c] x) a)) && t.Uses == 1 && flagify(a) => ((EQ|NE) (Select1 <types.TypeFlags> a.Args[0]))
1664 ((EQ|NE) t:(TESTL a:(ADDLconst [c] x) a)) && t.Uses == 1 && flagify(a) => ((EQ|NE) (Select1 <types.TypeFlags> a.Args[0]))
1665
1666 // If we don't use the flags any more, just use the standard op.
1667 (Select0 a:(ADD(Q|L)constflags [c] x)) && a.Uses == 1 => (ADD(Q|L)const [c] x)
1668
View as plain text